media-gfx/opencsg: new version 1.4.0 to fix two bugs.

This fixes a version bump request from one of our users, and also a
build failure. Version 1.3.2 tried to link with QtGui, even though
that wasn't a declared dependency, causing the build to fail when it
was missing. The new v1.4.0 doesn't seem to have that problem, so the
build failure should be gone.

In the process, the ebuild was updated to use EAPI=6 and
qmake-utils.eclass.

Gentoo-Bug: 514210
Gentoo-Bug: 515124

Package-Manager: portage-2.2.28

diff --git a/media-gfx/opencsg/Manifest b/media-gfx/opencsg/Manifest
index c508e0d2b208a74c9f2f6cfa37b62232ab6e1b11..c066167c2ba3586ae836f6809d9d95caef7e9787 100644 (file)
--- a/media-gfx/opencsg/Manifest
+++ b/media-gfx/opencsg/Manifest
@@ -1 +1 @@
-DIST OpenCSG-1.3.2.tar.gz 744712 SHA256 c790c92998f7113cb35cde825f81c5532755908a0a3f43c3c3c8df2326b3b925 SHA512 12c4308234d61ae013db62039974178d49a7298fb18c9d4e431d3629c75c808e0892c6553f1676d991b50d69e26eeb6d6da1f1eea6b8b2785d06683f523ca0d8 WHIRLPOOL ed59764c861ede60dd430ad111613de92c44bbe6b9d5f33f6c0aee93671b7abb9ef266627f126820c877ee54a651aa0d560beaf1458cbce952e30ed88a6bf908
+DIST OpenCSG-1.4.0.tar.gz 852213 SHA256 ecb46be54cfb8a338d2a9b62dec90ec8da6c769078c076f58147d4a6ba1c878d SHA512 da465c07201002834787dbe79ec29898310f4d726d9c44072e5ce947078fd7342ab1347886cab53b7f75458989aa4218738a7a8969d03184dc5fdcc1f96ce190 WHIRLPOOL 1d29789275926c9847486314c693e33873d97aa3e74f892634c9b72ec2f518a4e5a048934346033dec731fd45be4f5f1755ab11465fc8488ebf0c5976946bc36

diff --git a/media-gfx/opencsg/opencsg-1.3.2-r1.ebuild b/media-gfx/opencsg/opencsg-1.3.2-r1.ebuild
deleted file mode 100644 (file)
index fcc9205..0000000
--- a/media-gfx/opencsg/opencsg-1.3.2-r1.ebuild
+++ /dev/null
@@ -1,40 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=4
-
-inherit qt4-r2
-
-DESCRIPTION="The Constructive Solid Geometry rendering library"
-HOMEPAGE="http://www.opencsg.org"
-SRC_URI="http://www.opencsg.org/OpenCSG-${PV}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-CDEPEND="media-libs/glew dev-qt/qtcore:4"
-DEPEND="${CDEPEND} sys-devel/gcc"
-RDEPEND="${CDEPEND}"
-
-S="${WORKDIR}/OpenCSG-${PV}"
-
-src_prepare() {
-       # removes duplicated headers
-       rm -r "${S}"/glew || die
-
-       # We actually want to install something
-       cat << EOF >> src/src.pro
-include.path=/usr/include
-include.files=../include/*
-target.path=/usr/$(get_libdir)
-INSTALLS += target include
-EOF
-
-}
-
-src_configure() {
-        eqmake4 "${S}"/src/src.pro
-}

diff --git a/media-gfx/opencsg/opencsg-1.4.0.ebuild b/media-gfx/opencsg/opencsg-1.4.0.ebuild
new file mode 100644 (file)
index 0000000..f9eb9d7
--- /dev/null
+++ b/media-gfx/opencsg/opencsg-1.4.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit qmake-utils
+
+MY_P="OpenCSG-${PV}"
+DESCRIPTION="The Constructive Solid Geometry rendering library"
+HOMEPAGE="http://www.opencsg.org"
+SRC_URI="http://www.opencsg.org/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+COMMON_DEPEND="media-libs/glew:0 dev-qt/qtcore:4"
+DEPEND="${COMMON_DEPEND}"
+RDEPEND="${COMMON_DEPEND}"
+
+S="${WORKDIR}/${MY_P}/src"
+
+src_prepare() {
+       default
+
+       # removes duplicated headers
+       rm -r ../glew || die "failed to remove bundled glew"
+
+       sed -i -e 's:^INSTALLDIR.*:INSTALLDIR = /usr:' src.pro \
+               || die 'failed to fix INSTALLDIR in src.pro'
+
+       sed -i -e "s:^target.path.*:target.path = \$\$INSTALLDIR/$(get_libdir):" \
+               src.pro \
+               || die 'failed to fix target.path in src.pro'
+}
+
+src_configure() {
+       eqmake4 src.pro
+}
+
+src_install() {
+       emake INSTALL_ROOT="${D}" install
+}