media-libs/libchamplain: version bump 0.12.15 → 0.12.16

Package-Manager: Portage-2.3.8, Repoman-2.3.3

diff --git a/media-libs/libchamplain/Manifest b/media-libs/libchamplain/Manifest
index d0cbdca28282fbc9150b5d74efd0568295cdc64f..d4ec5429a64e51a1234a1e6348e5bd4a9af00cae 100644 (file)
--- a/media-libs/libchamplain/Manifest
+++ b/media-libs/libchamplain/Manifest
@@ -1 +1,2 @@
 DIST libchamplain-0.12.15.tar.xz 616692 SHA256 54721a210bdef6d73c5192ed83542023117bf5d7441257e7a7a9f8c05550b874 SHA512 df921dc26e30bc32f6487c02fc3c3f2dc7c672f6f42bd79e05091f717e6545051ab4f0db0709152a5babd4bbd7eb122997682561d9d63bef19bc1b2923100437 WHIRLPOOL 8b771c21cf3227b9f07377d219124b7c8a6ddeefa48db8f9e76e0ef619e01afaab808f7b3ffb5b54baed69a117ff7396f94e82e8abe69e26fd8dff6f9b36a6e5
+DIST libchamplain-0.12.16.tar.xz 623912 SHA256 4a7e31cf7889669aebf04631543af64435edd989685159b804911c6005db908d SHA512 78db380d87bd6437cab84b546af7f6505a8aaed7e8d9e8a06f3fdab1896b06a3bf1d11201384e4daedd2c78e528221e1d7e40665557e78251efec5fa036f4137 WHIRLPOOL 828f0e4f3ebdc207b2526802cd8e63fad51b445388c4d7feda31ec585d7afb586a14bbd600fea1addacd31c6f4ae34fd9ead65a19343074a4934a3935d2ddc34

diff --git a/media-libs/libchamplain/libchamplain-0.12.16.ebuild b/media-libs/libchamplain/libchamplain-0.12.16.ebuild
new file mode 100644 (file)
index 0000000..80a76c7
--- /dev/null
+++ b/media-libs/libchamplain/libchamplain-0.12.16.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="Clutter based world map renderer"
+HOMEPAGE="https://wiki.gnome.org/Projects/libchamplain"
+
+SLOT="0.12"
+LICENSE="LGPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="debug +gtk +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+       dev-db/sqlite:3
+       >=dev-libs/glib-2.16:2
+       >=media-libs/clutter-1.12:1.0[introspection?]
+       media-libs/cogl:=
+       >=net-libs/libsoup-2.42:2.4
+       >=x11-libs/cairo-1.4
+       x11-libs/gtk+:3
+       gtk? (
+               x11-libs/gtk+:3[introspection?]
+               media-libs/clutter-gtk:1.0 )
+       introspection? ( dev-libs/gobject-introspection:= )
+"
+DEPEND="${RDEPEND}
+       dev-util/gtk-doc-am
+       virtual/pkgconfig
+       vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+       # Fix documentation slotability
+       sed \
+               -e "s/^DOC_MODULE.*/DOC_MODULE = ${PN}-${SLOT}/" \
+               -i docs/reference/Makefile.{am,in} || die "sed (1) failed"
+       sed \
+               -e "s/^DOC_MODULE.*/DOC_MODULE = ${PN}-gtk-${SLOT}/" \
+               -i docs/reference-gtk/Makefile.{am,in} || die "sed (2) failed"
+       mv "${S}"/docs/reference/${PN}{,-${SLOT}}-docs.sgml || die "mv (1) failed"
+       mv "${S}"/docs/reference-gtk/${PN}-gtk{,-${SLOT}}-docs.sgml || die "mv (2) failed"
+
+       use vala && vala_src_prepare
+       gnome2_src_prepare
+}
+
+src_configure() {
+       # Vala demos are only built, so just disable them
+       gnome2_src_configure \
+               --disable-memphis \
+               --disable-static \
+               --disable-vala-demos \
+               $(use_enable debug) \
+               $(use_enable gtk) \
+               $(use_enable introspection) \
+               $(use_enable vala)
+}