gui-apps/waybar: subslot libmfmt to 0/5

Closes: https://bugs.gentoo.org/692920
Package-Manager: Portage-2.3.73, Repoman-2.3.17
Signed-off-by: Bernardo Meurer <bernardo@standard.ai>
Signed-off-by: Aaron Bauman <bman@gentoo.org>

diff --git a/gui-apps/waybar/waybar-0.7.2-r1.ebuild b/gui-apps/waybar/waybar-0.7.2-r1.ebuild
new file mode 100644 (file)
index 0000000..c261925
--- /dev/null
+++ b/gui-apps/waybar/waybar-0.7.2-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+DESCRIPTION="Highly customizable Wayland bar for Sway and Wlroots based compositors."
+HOMEPAGE="https://github.com/Alexays/Waybar"
+
+if [[ ${PV} == 9999 ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/Alexays/${PN^}.git"
+else
+       SRC_URI="https://github.com/Alexays/${PN^}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="libcxx mpd network pulseaudio tray +udev"
+
+DEPEND="
+       dev-cpp/gtkmm:3.0
+       dev-libs/jsoncpp:=
+       dev-libs/libinput:=
+       dev-libs/libsigc++:2
+       >=dev-libs/libfmt-5.3.0:0/5
+       >=dev-libs/spdlog-1.3.1:=
+       dev-libs/wayland
+       dev-libs/wayland-protocols
+       gui-libs/wlroots
+       libcxx? ( sys-libs/libcxx )
+       mpd? ( media-libs/libmpdclient )
+       network? ( dev-libs/libnl:3 )
+       pulseaudio? ( media-sound/pulseaudio )
+       tray? ( dev-libs/libdbusmenu[gtk3] )
+       udev? ( virtual/libudev:= )"
+
+RDEPEND="${DEPEND}"
+
+BDEPEND="virtual/pkgconfig"
+
+if [[ ${PV} != 9999 ]]; then
+       S="${WORKDIR}/${PN^}-${PV}"
+fi
+
+src_configure() {
+       local emesonargs=(
+               $(meson_use libcxx)
+               $(meson_feature mpd)
+               $(meson_feature network libnl)
+               $(meson_feature pulseaudio)
+               $(meson_feature tray dbusmenu-gtk)
+               $(meson_feature udev libudev)
+       )
+       meson_src_configure
+}

diff --git a/gui-apps/waybar/waybar-9999.ebuild b/gui-apps/waybar/waybar-9999.ebuild
index fc844ec121d282507d308a9c8129fba8b66637a7..c26192592d717adb264457b3d621ba8ae9fc9743 100644 (file)
--- a/gui-apps/waybar/waybar-9999.ebuild
+++ b/gui-apps/waybar/waybar-9999.ebuild
@@ -25,7 +25,7 @@ DEPEND="
        dev-libs/jsoncpp:=
        dev-libs/libinput:=
        dev-libs/libsigc++:2
-       >=dev-libs/libfmt-5.3.0:=
+       >=dev-libs/libfmt-5.3.0:0/5
        >=dev-libs/spdlog-1.3.1:=
        dev-libs/wayland
        dev-libs/wayland-protocols