dev-ada/gnatcoll-core: enable build with gnat-gpl-2019

Signed-off-by: Alfredo Tupone <tupone@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11

diff --git a/dev-ada/gnatcoll-core/gnatcoll-core-2018-r1.ebuild b/dev-ada/gnatcoll-core/gnatcoll-core-2018-r1.ebuild
new file mode 100644 (file)
index 0000000..5aee1f7
--- /dev/null
+++ b/dev-ada/gnatcoll-core/gnatcoll-core-2018-r1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit multiprocessing
+
+MYP=${PN}-gpl-${PV}
+
+DESCRIPTION="GNAT Component Collection Core packages"
+HOMEPAGE="http://libre.adacore.com"
+SRC_URI="http://mirrors.cdn.adacore.com/art/5b0819dfc7a447df26c27a99
+       -> ${MYP}-src.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnat_2016 gnat_2017 +gnat_2018 gnat_2019 +shared static-libs static-pic"
+
+RDEPEND="
+       dev-ada/libgpr[gnat_2016=,gnat_2017=,gnat_2018=,gnat_2019=]
+       dev-ada/libgpr[shared?,static-libs?,static-pic?]
+       !dev-ada/gnatcoll"
+DEPEND="${RDEPEND}
+       dev-ada/gprbuild[gnat_2016=,gnat_2017=,gnat_2018=,gnat_2019=]"
+
+S="${WORKDIR}"/${MYP}-src
+
+PATCHES=( "${FILESDIR}"/${P}-gentoo.patch )
+
+src_prepare() {
+       if use gnat_2016; then
+               GCC_PV=4.9.4
+       elif use gnat_2017; then
+               GCC_PV=6.3.0
+       elif use gnat_2018; then
+               GCC_PV=7.3.1
+       else
+               GCC_PV=8.3.1
+       fi
+       default
+       sed -i \
+               -e "s:@GNATLS@:${CHOST}-gnatls-${GCC_PV}:g" \
+               src/gnatcoll-projects.ads \
+               || die
+}
+
+src_configure() {
+       emake prefix="${D}usr" PROCESSORS=$(makeopts_jobs) setup
+}
+
+src_compile() {
+       build () {
+               gprbuild -p -m -j$(makeopts_jobs) \
+                       -XBUILD=PROD -v -XGNATCOLL_VERSION=${PV} \
+                       -XLIBRARY_TYPE=$1 -XXMLADA_BUILD=$* -XGPR_BUILD=$1 \
+                       gnatcoll.gpr -cargs:C ${CFLAGS} -cargs:Ada ${ADAFLAGS} || die
+       }
+       if use shared; then
+               build relocatable
+       fi
+       if use static-pic; then
+               build static-pic
+       fi
+       if use static-libs; then
+               build static
+       fi
+}
+
+src_install() {
+       if use shared; then
+               emake install-relocatable
+       fi
+       if use static-pic; then
+               emake install-static-pic
+       fi
+       if use static-libs; then
+               emake install-static
+       fi
+       rm -r "${D}"/usr/share/gpr/manifests || die
+       einstalldocs
+}

diff --git a/dev-ada/gnatcoll-core/metadata.xml b/dev-ada/gnatcoll-core/metadata.xml
index 294071cbcd12b2f2f99f5b4beff3601308d5450a..5065682aa1e5f1106e5d2203b1d5ffb9baf13d89 100644 (file)
--- a/dev-ada/gnatcoll-core/metadata.xml
+++ b/dev-ada/gnatcoll-core/metadata.xml
@@ -9,6 +9,7 @@
                <flag name="gnat_2016">Compile with dev-lang/gnat-gpl-2016</flag>
                <flag name="gnat_2017">Compile with dev-lang/gnat-gpl-2017</flag>
                <flag name="gnat_2018">Compile with dev-lang/gnat-gpl-2018</flag>
+               <flag name="gnat_2019">Compile with dev-lang/gnat-gpl-2018</flag>
                <flag name="shared">Build shared library</flag>
                <flag name="static-pic">Build static library with pic code</flag>
        </use>