dev-util/diffuse: a new version for python3, pygobject and gtk3

Bug: https://bugs.gentoo.org/708074
Package-Manager: Portage-2.3.87, Repoman-2.3.20
Signed-off-by: Andrey Grozin <grozin@gentoo.org>

diff --git a/dev-util/diffuse/Manifest b/dev-util/diffuse/Manifest
index 58c91e54731ee48b4044e57979ea167405238ef5..9700495ff272d50b603788f00b59857f84f4055a 100644 (file)
--- a/dev-util/diffuse/Manifest
+++ b/dev-util/diffuse/Manifest
@@ -1 +1,2 @@
 DIST diffuse-0.4.8.tar.bz2 557966 BLAKE2B 97879c41db390c9e3f0b0634ab34b33021013aaa8e28b0afe98a1131772803129fa81ccc6532a921d28f0eee51c4ccfbecb400645ed4141e6d2fe669e552014e SHA512 0c62976526804a328f1cc1775f842e9575fab50309cc964171af5ee89d8f303d4cbdf66a078ed64bb8826f5a57c2cc7fc59afc1ee87646ece340212d34f2514e
+DIST diffuse-0.5.0_alpha7.tar.xz 531124 BLAKE2B e97b8dd1b24253c4049dd4dc0f185049f030163945d822c3dbf6763f14eff270ed6bea82ae55b6cecaaa0f90976aab286db53c3f69d54f708e403832f8b2b1c1 SHA512 280d2c3c698affbf91b0e25ba658133999ea9b0199d8c165e2cef05210386f0fb3ff8611710903c1a3cb13aed01a648d04b3b8b13227f96803b74adbebf62adf

diff --git a/dev-util/diffuse/diffuse-0.5.0_alpha7.ebuild b/dev-util/diffuse/diffuse-0.5.0_alpha7.ebuild
new file mode 100644 (file)
index 0000000..eb5c6a2
--- /dev/null
+++ b/dev-util/diffuse/diffuse-0.5.0_alpha7.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+PLOCALES="cs de es it ja ko pl pt ru sv th zh_CN zh_TW"
+inherit python-single-r1 l10n xdg-utils
+
+DESCRIPTION="A graphical tool to compare and merge text files"
+HOMEPAGE="http://diffuse.sourceforge.net/ https://github.com/MightyCreak/diffuse/"
+SRC_URI="https://dev.gentoo.org/~grozin/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+       dev-python/pygobject[${PYTHON_USEDEP},cairo]
+       x11-libs/gtk+:3[introspection]"
+# file collision, bug #279018
+DEPEND="${DEPEND}
+       !sci-chemistry/tinker"
+
+src_prepare() {
+       default
+       l10n_find_plocales_changes translations '' '.po'
+
+       rm_locale() {
+               rm -f translations/${1}.po
+               rm -rf src/usr/share/man/${1}
+               rm -rf src/usr/share/gnome/help/${PN}/$1
+               rm -f src/usr/share/omf/${PN}/${PN}-$1.omf
+       }
+
+       l10n_for_each_disabled_locale_do rm_locale
+}
+
+src_install() {
+       "${PYTHON}" install.py \
+               --prefix="${EPREFIX}"/usr \
+               --sysconfdir="${EPREFIX}"/etc \
+               --files-only \
+               --destdir="${D}" \
+               || die "Installation failed"
+       dodoc AUTHORS ChangeLog README.md
+}
+
+pkg_postinst() {
+       xdg_desktop_database_update
+       xdg_icon_cache_update
+}
+
+pkg_postrm() {
+       xdg_desktop_database_update
+       xdg_icon_cache_update
+}