app-misc/mc: bump up to 4.8.22

Package-Manager: Portage-2.3.53, Repoman-2.3.12
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

diff --git a/app-misc/mc/Manifest b/app-misc/mc/Manifest
index 9967ef41480924f0df62df934f43dc34cfa9d542..1424ab6aa800f63a1004471a70058c2161c8c594 100644 (file)
--- a/app-misc/mc/Manifest
+++ b/app-misc/mc/Manifest
@@ -1,2 +1,3 @@
 DIST mc-4.8.20.tar.xz 2529580 BLAKE2B 14e575b650d28e0dcaa8ef0dc0b8e9bbf3e840ddc3d34d20518d28a6b253a8769c041c29ef7136c5fb72bd6130b0fc6c367dab8e44e040ef6dfd5406c364b86c SHA512 c2460561ae94bed75b1ed12f5c8039c9f8ace4c06987c57d07b8399c4e01c5a6c57851fddb3e918a4541ade089c89e8526078572a09580ccd0ae95344e3c1138
 DIST mc-4.8.21.tar.xz 2528292 BLAKE2B 0cbebcd2284f9ed9687022280aa1ba9e4a5960c6f1de27e5f4bab1b9bf205077dec2851e47b787aa6aec9cac28d467bf58ee2647a592e194ab3bfc63138b373f SHA512 db1a252744b47ebf5339ad204d8b69cb914f25ade7fe5aae2650c4abb57478715d3b7b3a24f4460adfb9fbdc928e8728b369b4f1709215e5e9af3d430fce6acf
+DIST mc-4.8.22.tar.xz 2538524 BLAKE2B f7839177dfb02d5b56d6a4ae1f045f7bc501b70fc845efaa6d45ef8e432ec680e51e4530aa5aa25c33ad339171d1ff435f6a1c5dbc5ac150053c64101b7a5c30 SHA512 834d467a4561fe4361bbde61be2c9ded95ade2a89855d953f58b7bfeb21297a3d6ebf674e72ac665b1794e0cbc8da752bc14fb37b129ff870856b339091f6bed

diff --git a/app-misc/mc/mc-4.8.22.ebuild b/app-misc/mc/mc-4.8.22.ebuild
new file mode 100644 (file)
index 0000000..d6f2ab5
--- /dev/null
+++ b/app-misc/mc/mc-4.8.22.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic
+
+MY_P=${P/_/-}
+
+DESCRIPTION="GNU Midnight Commander is a text based file manager"
+HOMEPAGE="https://www.midnight-commander.org"
+SRC_URI="http://ftp.midnight-commander.org/${MY_P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x86-solaris"
+IUSE="+edit gpm mclib nls samba sftp +slang spell test unicode X +xdg"
+
+REQUIRED_USE="spell? ( edit )"
+
+RDEPEND=">=dev-libs/glib-2.26.0:2
+       gpm? ( sys-libs/gpm )
+       kernel_linux? ( sys-fs/e2fsprogs )
+       samba? ( net-fs/samba )
+       sftp? ( net-libs/libssh2 )
+       slang? ( >=sys-libs/slang-2 )
+       !slang? ( sys-libs/ncurses:0=[unicode?] )
+       spell? ( app-text/aspell )
+       X? ( x11-libs/libX11
+               x11-libs/libICE
+               x11-libs/libXau
+               x11-libs/libXdmcp
+               x11-libs/libSM )"
+DEPEND="${RDEPEND}
+       app-arch/xz-utils
+       virtual/pkgconfig
+       nls? ( sys-devel/gettext )
+       test? ( dev-libs/check )
+       "
+
+S=${WORKDIR}/${MY_P}
+
+pkg_pretend() {
+       if use slang && use unicode ; then
+               ewarn "\"unicode\" USE flag only takes effect when the \"slang\" USE flag is disabled."
+       fi
+}
+
+src_configure() {
+       [[ ${CHOST} == *-solaris* ]] && append-ldflags "-lnsl -lsocket"
+
+       local myeconfargs=(
+               --disable-dependency-tracking
+               --disable-silent-rules
+               --enable-charset
+               --enable-vfs
+               --with-homedir=$(usex xdg 'XDG' '.mc')
+               --with-screen=$(usex slang 'slang' "ncurses$(usex unicode 'w' '')")
+               $(use_enable kernel_linux vfs-undelfs)
+               $(use_enable mclib)
+               $(use_enable nls)
+               $(use_enable samba vfs-smb)
+               $(use_enable sftp vfs-sftp)
+               $(use_enable spell aspell)
+               $(use_enable test tests)
+               $(use_with gpm gpm-mouse)
+               $(use_with X x)
+               $(use_with edit internal-edit)
+       )
+       econf "${myeconfargs[@]}"
+}
+
+src_install() {
+       emake DESTDIR="${D}" install
+       dodoc AUTHORS README NEWS
+
+       # fix bug #334383
+       if use kernel_linux && [[ ${EUID} == 0 ]] ; then
+               fowners root:tty /usr/libexec/mc/cons.saver
+               fperms g+s /usr/libexec/mc/cons.saver
+       fi
+
+       if ! use xdg ; then
+               sed 's@MC_XDG_OPEN="xdg-open"@MC_XDG_OPEN="/bin/false"@' \
+                       -i "${ED%/}"/usr/libexec/mc/ext.d/*.sh || die
+       fi
+}
+
+pkg_postinst() {
+       elog "To enable exiting to latest working directory,"
+       elog "put this into your ~/.bashrc:"
+       elog ". ${EPREFIX}/usr/libexec/mc/mc.sh"
+}

diff --git a/app-misc/mc/mc-9999.ebuild b/app-misc/mc/mc-9999.ebuild
index 3af128d35dc47d8c7c1d72c683c8e2123e3a428a..722ae657e0d8d944ad552a1812e69ea4d5238bf3 100644 (file)
--- a/app-misc/mc/mc-9999.ebuild
+++ b/app-misc/mc/mc-9999.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
 if [[ ${PV} = *9999* ]]; then
        EGIT_REPO_URI="https://github.com/MidnightCommander/mc.git"
@@ -68,7 +68,7 @@ src_configure() {
                --enable-charset
                --enable-vfs
                --with-homedir=$(usex xdg 'XDG' '.mc')
-               --with-screen=$(usex slang 'slang' "ncurses$(usex unicode 'w')")
+               --with-screen=$(usex slang 'slang' "ncurses$(usex unicode 'w' '')")
                $(use_enable kernel_linux vfs-undelfs)
                $(use_enable mclib)
                $(use_enable nls)