dev-libs/gom: bump to 0.3.3

Brought over from the gnome overlay with the following changes:

- port to EAPI=7
- simplify meson/python-r1 interactions
- remove broken DESTDIR argument when calling meson_src_install
- properly generate .pyc files (QA warning)

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Rémi Cardona <remi@gentoo.org>

diff --git a/dev-libs/gom/Manifest b/dev-libs/gom/Manifest
index 4e42e95052ded08f1d5f6eda21b3dedcb052eec4..e44cf06de9324a8b13eef46b47f7d06646c05848 100644 (file)
--- a/dev-libs/gom/Manifest
+++ b/dev-libs/gom/Manifest
@@ -1 +1,2 @@
 DIST gom-0.3.2.tar.xz 410300 BLAKE2B c0c79c1c3f8a28a0ee992fa4c316538eb87ec26c77def353e8b2038e32f30f9daed433c6d6f6c81069e05e46a980f7d944c955182d973d42f3bd84a341c5a34d SHA512 a7bfb263e5ff6f89768d8fcbdcc949d4ec9b82ecbb80952becd357a3d5781a60e52a327e865e39e46d542b2a2c5e5c861e5302d7ae3c3a2258d3c3f698263675
+DIST gom-0.3.3.tar.xz 101580 BLAKE2B 08e0abb9eaf23ba3bbbca54289ebaa695af705e65b9b612f125e72c62f337baec899d16e657d3de51baeb4ffb79b583716a01d74067e256d59e1dcb63723273e SHA512 152924e704c92f39c493a8becc73fac1f7fe396f4f9e7c154dccec2b4413476821e43abf3c108cc1304de471e61f56c265f124710379ad8568b68f8902064e03

diff --git a/dev-libs/gom/gom-0.3.3.ebuild b/dev-libs/gom/gom-0.3.3.ebuild
new file mode 100644 (file)
index 0000000..9a9ca3d
--- /dev/null
+++ b/dev-libs/gom/gom-0.3.3.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+GCONF_DEBUG="yes"
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit gnome.org gnome2-utils meson python-r1
+
+DESCRIPTION="GObject to SQLite object mapper library"
+HOMEPAGE="https://wiki.gnome.org/Projects/Gom"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc +introspection test"
+
+RDEPEND="
+       >=dev-db/sqlite-3.7:3
+       >=dev-libs/glib-2.36:2
+       introspection? ( >=dev-libs/gobject-introspection-1.30.0:= )
+       ${PYTHON_DEPS}
+       >=dev-python/pygobject-3.16:3[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+       doc? ( dev-util/gtk-doc )
+       >=dev-util/intltool-0.40.0
+       sys-devel/gettext
+       virtual/pkgconfig
+       test? ( x11-libs/gdk-pixbuf:2 )
+"
+# TODO: make gdk-pixbuf properly optional with USE=test
+
+pkg_setup() {
+       python_setup
+}
+
+src_configure() {
+       local emesonargs=(
+               $(meson_use introspection enable-introspection)
+               $(meson_use doc enable-gtk-doc)
+       )
+
+       python_foreach_impl meson_src_configure
+}
+
+src_compile() {
+       python_foreach_impl meson_src_compile
+}
+
+src_install() {
+       docinto examples
+       dodoc examples/*.py
+
+       installing() {
+               meson_src_install
+               python_optimize
+       }
+       python_foreach_impl installing
+}
+
+src_test() {
+       # tests may take a long time
+       python_foreach_impl meson_src_test
+}