gnome-extra/gnome-software: initial ebuild, bug #565212

Imported from gnome-overlay.

Package-Manager: portage-2.2.26

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
new file mode 100644 (file)
index 0000000..0f691a0
--- /dev/null
+++ b/gnome-extra/gnome-software/Manifest
@@ -0,0 +1 @@
+DIST gnome-software-3.18.3.tar.xz 2195300 SHA256 cc76a51f56d114018f64478437aebef068799802884543c59e2473066c959b7b SHA512 61d4f9622d0f3c6b65d271a79908713f1ee5a2da67275aee6cd6510d6c124ad76300bcc696846d8bd95843f9326534218d3b140445f6e7d2f6ab8d336e476ec0 WHIRLPOOL acea5e54b06bcd2d1088d7790b813001a2718acd981c53f4dca170200efc96ca2d6e477ff674f384e08817821697ef2e2261d4d14cf5f3bd4c757352920231de

diff --git a/gnome-extra/gnome-software/gnome-software-3.18.3.ebuild b/gnome-extra/gnome-software/gnome-software-3.18.3.ebuild
new file mode 100644 (file)
index 0000000..8e0fdb1
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-3.18.3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1 virtualx
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="http://wiki.gnome.org/Apps/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RDEPEND="
+       >=app-admin/packagekit-base-1.0.9
+       dev-db/sqlite:3
+       >=dev-libs/appstream-glib-0.5.1:0
+       >=dev-libs/glib-2.45.8:2
+       >=gnome-base/gnome-desktop-3.17.92:3=
+       >=gnome-base/gsettings-desktop-schemas-3.11.5
+       net-libs/libsoup:2.4
+       sys-auth/polkit
+       >=x11-libs/gtk+-3.16:3
+"
+DEPEND="${RDEPEND}
+       ${PYTHON_DEPS}
+       app-text/docbook-xml-dtd:4.2
+       dev-libs/libxslt
+       >=dev-util/intltool-0.35
+       virtual/pkgconfig
+       test? ( dev-util/dogtail )
+"
+# test? ( dev-util/valgrind )
+
+pkg_setup() {
+       python-any-r1_pkg_setup
+}
+
+src_prepare() {
+       # valgrind fails with SIGTRAP
+       sed -e 's/TESTS = .*/TESTS =/' \
+               -i "${S}"/src/Makefile.{am,in} || die
+
+       gnome2_src_prepare
+}
+
+src_configure() {
+       # FIXME: investigate limba and firmware update support
+       gnome2_src_configure \
+               --enable-man \
+               --disable-firmware \
+               --disable-limba \
+               $(use_enable test dogtail)
+}
+
+src_test() {
+       Xemake check TESTS_ENVIRONMENT="dbus-run-session"
+}

diff --git a/gnome-extra/gnome-software/metadata.xml b/gnome-extra/gnome-software/metadata.xml
new file mode 100644 (file)
index 0000000..6e0e2ec
--- /dev/null
+++ b/gnome-extra/gnome-software/metadata.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>gnome</herd>
+</pkgmetadata>