x11-wm/enlightenment: version bump to 0.20.5 #573784

diff --git a/x11-wm/enlightenment/Manifest b/x11-wm/enlightenment/Manifest
index d8c572a580361db6667767368f554858c3aeb9b2..c4256568fe7a8a275974a6d3c755c80786f7473a 100644 (file)
--- a/x11-wm/enlightenment/Manifest
+++ b/x11-wm/enlightenment/Manifest
@@ -5,3 +5,4 @@ DIST enlightenment-0.19.10.tar.xz 24594372 SHA256 8bdc2b764765e807df263962cb3c47
 DIST enlightenment-0.19.12.tar.xz 24569084 SHA256 55f23c337e3092e735ae37ada8f6701adab5ddd13f37ef38c63eec8a536f0b25 SHA512 30332fa0108a4361dd7cc961325b607fccef99caa1db6eaf068fc97de9978ad21dde5724a7e8f6612441fb0529a56461c8df63de25579f67d452fa9bf382d859 WHIRLPOOL e19f84c4a6311ef583d8f2bd53bc85a13e37bc65bdccc1823953685e0946f18cfaf0a75ee97f1a97e5d7fb9c9b0711b92f00f6949e5ca44718b6bf2347cb3a4c
 DIST enlightenment-0.20.1.tar.xz 25038128 SHA256 820b14ab3decd585a011973d97efc0679a90f803b9d72f0726166a3262c1f4ee SHA512 6afffebfe5d223c288f80589b105badcfbd34c9277078fa7704937ae5173d2b866c57c2aee46d7cae9a6c9ac8d59f0b62bb0081e819b69a37d48571cbfc492cb WHIRLPOOL b4428665554086e6d97b42687a683d0facc25ec3013a2c91cbccce4943edb0541667db243268692a5e9f9a86231a1a0104548e887986baa64c480074eb0360fb
 DIST enlightenment-0.20.2.tar.xz 25037464 SHA256 441009a5cbe19861bc1f1404ce4361184ace27208ce429a51c23344c8f9f5d39 SHA512 7d6c5a0a435bbbe999848272ad017d5e914566aa3b833a423bfe21ffeabad17d8a6e91fc597c6ecfd94638c907aa24960a0d017bb4f3f0555875a4ca202415a8 WHIRLPOOL 333b36297ca01b243063e9470eb814b0aafebe25d1a3d58892a7a559455ee08671bb29878eb920df34e06b0fccafeafdbb45bde03fc587a0eea9f054046c5102
+DIST enlightenment-0.20.5.tar.xz 25039672 SHA256 22749584d2fdf62d5a63c64dd9e57a1e318837a48f10fb9cdd2097769aa802d0 SHA512 0d66d23b3462d6bf293229256d88d486d05135ff7bc7ab4258c3923c853f1935a1850b3a3ff0dabb1aae99a31dafb578f5cbb5678d08df490d3c6837b874a911 WHIRLPOOL 5bfa8e6cc2d5d17fc61a08fc9edbc8970f60cb9e44fcfaf7035b764d21525b375ce9f4060ac33a45627cc3a1f2eb21335e322f88f8a79709fce9284aa668d983

diff --git a/x11-wm/enlightenment/enlightenment-0.17.9999.ebuild b/x11-wm/enlightenment/enlightenment-0.17.9999.ebuild
index 3b6c43a8c67cbfac7d99e10a21119e1bbd6c1d86..05e09ca4fd900716b346a3344f699e9ce5b216d5 100644 (file)
--- a/x11-wm/enlightenment/enlightenment-0.17.9999.ebuild
+++ b/x11-wm/enlightenment/enlightenment-0.17.9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -11,7 +11,7 @@ if [[ ${PV} == *9999 ]] ; then
        EGIT_URI_APPEND="${PN}"
 else
        SRC_URI="https://download.enlightenment.org/rel/apps/${PN}/${MY_P}.tar.xz"
-       EKEY_STATE="live"
+       EKEY_STATE="snap"
 fi
 
 inherit enlightenment
@@ -54,8 +54,8 @@ RDEPEND="
                >=x11-libs/pixman-0.31.1
                >=x11-libs/libxkbcommon-0.3.1
        )
-       >=dev-libs/efl-1.16[X]
-       >=media-libs/elementary-1.16
+       >=dev-libs/efl-1.17[X]
+       >=media-libs/elementary-1.17
        x11-libs/xcb-util-keysyms"
 DEPEND="${RDEPEND}"
 

diff --git a/x11-wm/enlightenment/enlightenment-0.20.5.ebuild b/x11-wm/enlightenment/enlightenment-0.20.5.ebuild
new file mode 100644 (file)
index 0000000..05e09ca
--- /dev/null
+++ b/x11-wm/enlightenment/enlightenment-0.20.5.ebuild
@@ -0,0 +1,128 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+MY_P=${P/_/-}
+
+if [[ ${PV} == *9999 ]] ; then
+       EGIT_SUB_PROJECT="core"
+       EGIT_URI_APPEND="${PN}"
+else
+       SRC_URI="https://download.enlightenment.org/rel/apps/${PN}/${MY_P}.tar.xz"
+       EKEY_STATE="snap"
+fi
+
+inherit enlightenment
+
+DESCRIPTION="Enlightenment DR17 window manager"
+
+LICENSE="BSD-2"
+SLOT="0.17/${PV%%_*}"
+
+__CONF_MODS=(
+       applications bindings dialogs display
+       interaction intl menus
+       paths performance randr shelves theme
+       window-manipulation window-remembers
+)
+__NORM_MODS=(
+       appmenu backlight bluez4 battery
+       clock conf connman cpufreq everything
+       fileman fileman-opinfo gadman geolocation
+       ibar ibox lokker
+       mixer msgbus music-control notification
+       pager packagekit pager-plain policy-mobile quickaccess
+       shot start syscon systray tasks teamwork temperature tiling
+       winlist wizard wl-desktop-shell wl-drm wl-text-input
+       wl-weekeyboard wl-wl wl-x11 xkbswitch xwayland
+)
+IUSE_E_MODULES=(
+       ${__CONF_MODS[@]/#/enlightenment_modules_conf-}
+       ${__NORM_MODS[@]/#/enlightenment_modules_}
+)
+
+IUSE="pam spell static-libs systemd +udev ukit wayland ${IUSE_E_MODULES[@]/#/+}"
+
+RDEPEND="
+       pam? ( sys-libs/pam )
+       systemd? ( sys-apps/systemd )
+       wayland? (
+               dev-libs/efl[wayland]
+               >=dev-libs/wayland-1.2.0
+               >=x11-libs/pixman-0.31.1
+               >=x11-libs/libxkbcommon-0.3.1
+       )
+       >=dev-libs/efl-1.17[X]
+       >=media-libs/elementary-1.17
+       x11-libs/xcb-util-keysyms"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+       epatch "${FILESDIR}"/quickstart.diff
+       enlightenment_src_prepare
+}
+
+# Sanity check to make sure module lists are kept up-to-date.
+check_modules() {
+       local detected=$(
+               awk -F'[\\[\\](, ]' '$1 == "AC_E_OPTIONAL_MODULE" { print $3 }' \
+               configure.ac | sed 's:_:-:g' | LC_COLLATE=C sort
+       )
+       local sorted=$(
+               printf '%s\n' ${IUSE_E_MODULES[@]/#enlightenment_modules_} | \
+               LC_COLLATE=C sort
+       )
+       if [[ ${detected} != "${sorted}" ]] ; then
+               local out new old
+               eerror "The ebuild needs to be kept in sync."
+               echo "${sorted}" > ebuild-iuse
+               echo "${detected}" > configure-detected
+               out=$(diff -U 0 ebuild-iuse configure-detected | sed -e '1,2d' -e '/^@@/d')
+               new=$(echo "${out}" | sed -n '/^+/{s:^+::;p}')
+               old=$(echo "${out}" | sed -n '/^-/{s:^-::;p}')
+               eerror "Add these modules: $(echo ${new})"
+               eerror "Drop these modules: $(echo ${old})"
+               die "please update the ebuild"
+       fi
+}
+
+src_configure() {
+       check_modules
+
+       E_ECONF=(
+               --disable-install-sysactions
+               $(use_enable doc)
+               $(use_enable nls)
+               $(use_enable pam)
+               $(use_enable systemd)
+               --enable-device-udev
+               $(use_enable udev mount-eeze)
+               $(use_enable ukit mount-udisks)
+               $(use_enable wayland)
+       )
+       local u c
+       for u in ${IUSE_E_MODULES[@]} ; do
+               c=${u#enlightenment_modules_}
+               # Disable modules by hand since we default to enabling them all.
+               case ${c} in
+               wl-*|xwayland)
+                       if ! use wayland ; then
+                               E_ECONF+=( --disable-${c} )
+                               continue
+                       fi
+                       ;;
+               esac
+               E_ECONF+=( $(use_enable ${u} ${c}) )
+       done
+       enlightenment_src_configure
+}
+
+src_install() {
+       enlightenment_src_install
+       insinto /etc/enlightenment
+       newins "${FILESDIR}"/gentoo-sysactions.conf sysactions.conf
+}