net-misc/ssvnc: Update EAPI

Package-Manager: Portage-2.3.19, Repoman-2.3.6

diff --git a/net-misc/ssvnc/ssvnc-1.0.29-r1.ebuild b/net-misc/ssvnc/ssvnc-1.0.29-r1.ebuild
new file mode 100644 (file)
index 0000000..d052415
--- /dev/null
+++ b/net-misc/ssvnc/ssvnc-1.0.29-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils multilib toolchain-funcs
+
+DESCRIPTION="VNC viewer that adds encryption security to VNC connections"
+HOMEPAGE="http://www.karlrunge.com/x11vnc/ssvnc.html"
+SRC_URI="mirror://sourceforge/ssvnc/${P}.src.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~arm-linux ~x86-linux"
+IUSE="java"
+
+RDEPEND="sys-libs/zlib
+       virtual/jpeg
+       dev-libs/openssl
+       dev-lang/tk
+       net-misc/stunnel
+       java? ( virtual/jre )
+       x11-terms/xterm
+       x11-libs/libICE
+       x11-libs/libSM
+       x11-libs/libXaw
+       x11-libs/libX11
+       x11-libs/libXext
+       x11-libs/libXmu
+       x11-libs/libXp
+       x11-libs/libXpm
+       x11-libs/libXt"
+DEPEND="${RDEPEND}
+       java? ( virtual/jdk )"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.0.29-build.patch )
+
+src_prepare() {
+       default
+
+       sed -i \
+               -e "/^LIB/s:lib/:$(get_libdir)/:" \
+               -e "$(use java || echo '/^JSRC/s:=.*:=:')" \
+               Makefile || die
+       sed -i \
+               -e '/^CC/s:=.*:+= $(CFLAGS) $(CPPFLAGS) $(LDFLAGS):' \
+               vncstorepw/Makefile || die
+
+       cp "${FILESDIR}"/Makefile.libvncauth vnc_unixsrc/libvncauth/Makefile || die
+       cd "${S}"/vnc_unixsrc/vncviewer || die
+       sed -n '/^SRCS/,/^$/p' Imakefile > Makefile.in || die
+       cp "${FILESDIR}"/Makefile.vncviewer Makefile || die
+}
+
+src_compile() {
+       tc-export AR CC CXX RANLIB
+       emake all
+}
+
+src_install() {
+       emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+       dodoc README
+}