x11-wm/ratpoison: Version bump.

Package-Manager: Portage-2.3.5, Repoman-2.3.2

diff --git a/x11-wm/ratpoison/Manifest b/x11-wm/ratpoison/Manifest
index e6ffb24851bf480da13c67907c2bc4c88921bff1..c0552ec7185b9b0981e0c4e20d3e9b88fe81861a 100644 (file)
--- a/x11-wm/ratpoison/Manifest
+++ b/x11-wm/ratpoison/Manifest
@@ -1 +1,2 @@
 DIST ratpoison-1.4.8.tar.xz 364700 SHA256 da4695636d1fce8883ef2144d79ce46ebb0431a5da02440bd1ffec5dca17a0f0 SHA512 10b44489e60d3186ca407a5bd87e23dbd737cdafee22ea7284ac4db8bb4463081af483460d1899161fbae2973f4d25fbd1bfd354e3ffb59735baf69bbd6f94f6 WHIRLPOOL 53e087a28e685f7667ecbf2302db3df88382ac5840c898b3b8e7954f5c6de3b6f6928e8d021df30e5562991dab5c1c1b810556abc8fdef8979ffc062dd144426
+DIST ratpoison-1.4.9.tar.xz 315584 SHA256 d98fa4be025ecca453c407ff311ab3949f29f20d6d8abedf8f0716b85fc8d1f1 SHA512 97f705efd2092b8e12528496890c59f613e6fcec010aca94a5a59bd641e22dfc50dd500a4b94af7a07553a8a6359f6bec4eee0db1a7ded29d7f051904b09beef WHIRLPOOL 719aa36dce28b1cd0614e0e994f4109c3ade0d32fef7a295530f0c760c8bd3864b67ee3d2b5d9d45c89e059000721d0f564f40b33086c458f0a6df5876140e40

diff --git a/x11-wm/ratpoison/metadata.xml b/x11-wm/ratpoison/metadata.xml
index 652fb6eaaa83b5ba05b9ac13c27d8de9e3112346..00627b3495713bff1880af5f1c94c7c2553fe4eb 100644 (file)
--- a/x11-wm/ratpoison/metadata.xml
+++ b/x11-wm/ratpoison/metadata.xml
@@ -18,5 +18,6 @@
 <use>
        <flag name="history">Use <pkg>sys-libs/readline</pkg> for history handling</flag>
        <flag name="sloppy">Install sloppy, a focus-follows-mouse implementation for ratpoison</flag>
+       <flag name="xrandr">Enable support for XRandR</flag>
 </use>
 </pkgmetadata>

diff --git a/x11-wm/ratpoison/ratpoison-1.4.9.ebuild b/x11-wm/ratpoison/ratpoison-1.4.9.ebuild
new file mode 100644 (file)
index 0000000..f0c2e4d
--- /dev/null
+++ b/x11-wm/ratpoison/ratpoison-1.4.9.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit elisp-common eutils toolchain-funcs
+
+DESCRIPTION="window manager without mouse dependency"
+HOMEPAGE="http://www.nongnu.org/ratpoison/"
+SRC_URI="http://download.savannah.gnu.org/releases/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="debug emacs +history sloppy +xft +xrandr"
+
+RDEPEND="
+       emacs? ( virtual/emacs )
+       history? ( sys-libs/readline:= )
+       xft? ( x11-libs/libXft )
+       xrandr? ( x11-libs/libXrandr )
+       virtual/perl-Pod-Parser
+       x11-libs/libXtst
+"
+DEPEND="
+       ${RDEPEND}
+       virtual/pkgconfig
+       x11-proto/randrproto
+       x11-proto/xproto
+"
+
+SITEFILE=50ratpoison-gentoo.el
+DOCS=(
+       AUTHORS
+       ChangeLog
+       NEWS
+       README
+       TODO
+)
+
+PATCHES=(
+       "${FILESDIR}"/ratpoison.el-gentoo.patch
+)
+
+src_configure() {
+       econf \
+               $(use_enable debug) \
+               $(use_enable history) \
+               $(use_with xft) \
+               $(use_with xrandr) \
+               --without-electric-fence
+}
+
+src_compile() {
+       emake CFLAGS="${CFLAGS}"
+       if use emacs; then
+               elisp-compile contrib/ratpoison.el || die
+       fi
+
+       if use sloppy; then
+               pushd contrib
+               $(tc-getCC) \
+                       ${CFLAGS} \
+                       ${LDFLAGS} \
+                       -o sloppy{,.c} \
+                       $( $(tc-getPKG_CONFIG) --libs x11) \
+                       || die
+       fi
+}
+
+src_install() {
+       default
+
+       exeinto /etc/X11/Sessions
+       newexe "${FILESDIR}"/ratpoison.xsession ratpoison
+
+       insinto /usr/share/xsessions
+       doins "${FILESDIR}"/${PN}.desktop
+
+       use sloppy && dobin contrib/sloppy
+
+       docinto example
+       dodoc contrib/{genrpbindings,split.sh} \
+               doc/{ipaq.ratpoisonrc,sample.ratpoisonrc}
+
+       rm -rf "${ED}/usr/share/"{doc/ratpoison,ratpoison}
+
+       if use emacs; then
+               elisp-install ${PN} contrib/ratpoison.*
+               elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+       fi
+}
+
+pkg_postinst() {
+       use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+       use emacs && elisp-site-regen
+}

diff --git a/x11-wm/ratpoison/ratpoison-9999.ebuild b/x11-wm/ratpoison/ratpoison-9999.ebuild
index 0353bcb130d49c155711ff15b1974ee5615490d0..568ee3d06f2116d792baaef6bdd21a68e294637d 100644 (file)
--- a/x11-wm/ratpoison/ratpoison-9999.ebuild
+++ b/x11-wm/ratpoison/ratpoison-9999.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=6
 inherit autotools elisp-common eutils git-r3 toolchain-funcs
 
 DESCRIPTION="window manager without mouse dependency"
@@ -11,27 +11,35 @@ EGIT_REPO_URI="git://git.savannah.nongnu.org/ratpoison.git"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS=""
-IUSE="debug emacs +history sloppy +xft"
+IUSE="debug emacs +history sloppy +xft +xrandr"
 
 RDEPEND="
        emacs? ( virtual/emacs )
        history? ( sys-libs/readline:= )
        xft? ( x11-libs/libXft )
+       xrandr? ( x11-libs/libXrandr )
        virtual/perl-Pod-Parser
-       x11-libs/libXinerama
        x11-libs/libXtst
 "
 DEPEND="
        ${RDEPEND}
-       app-arch/xz-utils
        virtual/pkgconfig
+       x11-proto/randrproto
+       x11-proto/xproto
 "
 
 SITEFILE=50ratpoison-gentoo.el
-DOCS=( AUTHORS ChangeLog NEWS README TODO )
+DOCS=(
+       AUTHORS
+       ChangeLog
+       NEWS
+       README
+       TODO
+)
 
 src_prepare() {
-       epatch "${FILESDIR}"/ratpoison.el-gentoo.patch
+       eapply "${FILESDIR}"/ratpoison.el-gentoo.patch
+
        eautoreconf
 }
 
@@ -40,13 +48,14 @@ src_configure() {
                $(use_enable debug) \
                $(use_enable history) \
                $(use_with xft) \
+               $(use_with xrandr) \
                --without-electric-fence
 }
 
 src_compile() {
        emake CFLAGS="${CFLAGS}"
        if use emacs; then
-               elisp-compile contrib/ratpoison.el || die "elisp-compile failed"
+               elisp-compile contrib/ratpoison.el || die
        fi
 
        if use sloppy; then