net-libs/zeromq: OpenPGM is not bundled anymore, ./configure options changed.

Gentoo-Bug: https://bugs.gentoo.org/554608

Package-Manager: portage-2.2.24

diff --git a/net-libs/zeromq/zeromq-4.1.3-r1.ebuild b/net-libs/zeromq/zeromq-4.1.3-r1.ebuild
new file mode 100644 (file)
index 0000000..4b9f8b3
--- /dev/null
+++ b/net-libs/zeromq/zeromq-4.1.3-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=true
+
+inherit autotools-utils
+
+DESCRIPTION="A brokerless kernel"
+HOMEPAGE="http://www.zeromq.org/"
+SRC_URI="http://download.zeromq.org/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0/5"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="pgm static-libs test"
+
+RDEPEND="
+       dev-libs/libsodium:=
+       pgm? ( =net-libs/openpgm-5.2.122 )"
+DEPEND="${RDEPEND}
+       sys-apps/util-linux
+       pgm? ( virtual/pkgconfig )"
+
+src_prepare() {
+       sed \
+               -e '/libzmq_werror=/s:yes:no:g' \
+               -i configure.ac || die
+       autotools-utils_src_prepare
+}
+
+src_configure() {
+       local myeconfargs=(
+               --with-relaxed
+               --with-libsodium
+               $(use_with pgm)
+       )
+       autotools-utils_src_configure
+}
+
+src_test() {
+       autotools-utils_src_test -j1
+}
+
+src_install() {
+       autotools-utils_src_install
+
+       doman doc/*.[1-9]
+}