app-text/htmlrecode: EAPI7, improve ebuild

diff --git a/app-text/htmlrecode/htmlrecode-1.3.1-r1.ebuild b/app-text/htmlrecode/htmlrecode-1.3.1-r1.ebuild
new file mode 100644 (file)
index 0000000..4b92581
--- /dev/null
+++ b/app-text/htmlrecode/htmlrecode-1.3.1-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Recodes HTML file using a new character set"
+HOMEPAGE="https://bisqwit.iki.fi/source/htmlrecode.html"
+SRC_URI="https://bisqwit.iki.fi/src/arch/${P}.tar.bz2"
+
+KEYWORDS="~amd64 ~ppc ~x86"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+PATCHES=( "${FILESDIR}/${P}-ar.patch" )
+
+src_prepare() {
+       touch .depend argh/.depend || die
+       default
+}
+
+src_configure() { :; }
+
+src_compile() {
+       local makeopts=(
+               AR="$(tc-getAR)"
+               CPPDEBUG=
+               CXX="$(tc-getCXX)"
+               CXXFLAGS="${CXXFLAGS}"
+               LDFLAGS="${LDFLAGS}"
+       )
+       emake "${makeopts[@]}" -C argh libargh.a
+       emake "${makeopts[@]}" htmlrecode
+}
+
+src_install() {
+       dobin htmlrecode
+       dodoc README.html
+}