media-gfx/pqiv: version bump to 2.10.4

diff --git a/media-gfx/pqiv/Manifest b/media-gfx/pqiv/Manifest
index a346f2e60e433909e580e110e63bab03c8d4ac9d..f1b8f3b919f523408f2bc2696f3ba58fde257f3f 100644 (file)
--- a/media-gfx/pqiv/Manifest
+++ b/media-gfx/pqiv/Manifest
@@ -1 +1,2 @@
 DIST pqiv-2.10.2.tar.gz 138506 BLAKE2B 255104acec9d42eac52d8aaf05207fc8071ecbef14a04c5952e70347d0cd83b54b00725b9bb949184bcd9437982701814b6a09c4c2397336f26ce9f50896d2e6 SHA512 99cb3a187fa2cc0df7b7f768b2f801fbec78aa8d76aacd12085f3b8ccbfaf931a2379e7b05a92f83dacf511489518a75f9e5bf528e4152158d8bb75cffb0d6f7
+DIST pqiv-2.10.4.tar.gz 138644 BLAKE2B 7dc358379d463e6b421c082942a2171b749ea41b4e655c64425d6cfdf8f251ce89d431b45a28d8b30eb5c022814bec7e365c3b3272ebf0cc7e994b803ddfd4ec SHA512 52534ed4728466b7c710db65115d7e79ad97546750946fa5c3a26b65055387b15c6239fdf1bb8c8345fe7ed2dfc7ed5586ffa2a864de44fd8213cff59f76048a

diff --git a/media-gfx/pqiv/pqiv-2.10.4.ebuild b/media-gfx/pqiv/pqiv-2.10.4.ebuild
new file mode 100644 (file)
index 0000000..92c15ed
--- /dev/null
+++ b/media-gfx/pqiv/pqiv-2.10.4.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit linux-info toolchain-funcs xdg-utils
+
+if [[ ${PV} == 9999 ]]; then
+       EGIT_REPO_URI="https://github.com/phillipberndt/pqiv.git"
+       inherit git-r3
+else
+       SRC_URI="https://github.com/phillipberndt/pqiv/archive/${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="powerful GTK 3 based command-line image viewer with a minimal UI"
+HOMEPAGE="https://github.com/phillipberndt/pqiv http://www.pberndt.com/Programme/Linux/pqiv/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="archive ffmpeg imagemagick kernel_linux libav pdf postscript webp"
+
+RDEPEND="
+       >=dev-libs/glib-2.32:2
+       >=x11-libs/cairo-1.6
+       x11-libs/gtk+:3
+       archive? ( app-arch/libarchive:0= )
+       ffmpeg? (
+               !libav? ( media-video/ffmpeg:0= )
+               libav? ( media-video/libav:0= )
+       )
+       imagemagick? ( media-gfx/imagemagick:0= )
+       pdf? ( app-text/poppler:0= )
+       postscript? ( app-text/libspectre:0= )
+       webp? ( media-libs/libwebp:0= )
+"
+DEPEND="${RDEPEND}
+       virtual/pkgconfig"
+
+doecho() {
+       echo "$@"
+       "$@" || die
+}
+
+pkg_setup() {
+       if use kernel_linux; then
+               CONFIG_CHECK="~INOTIFY_USER"
+               linux-info_pkg_setup
+       fi
+}
+
+src_configure() {
+       local backends="gdkpixbuf"
+       use archive && backends+=",archive,archive_cbx"
+       use ffmpeg || use libav && backends+=",libav"
+       use imagemagick && backends+=",wand"
+       use pdf && backends+=",poppler"
+       use postscript && backends+=",spectre"
+       use webp && backends+=",webp"
+
+       doecho ./configure \
+               --backends-build=shared \
+               --backends=${backends} \
+               --prefix="${EPREFIX}/usr" \
+               --libdir="${EPREFIX}/usr/$(get_libdir)" \
+               --destdir="${ED}"
+}
+
+src_compile() {
+       tc-export CC
+       emake VERBOSE=1 CFLAGS="${CFLAGS}"
+}
+
+pkg_postinst() {
+       xdg_desktop_database_update
+}
+
+pkg_postrm() {
+       xdg_desktop_database_update
+}

diff --git a/media-gfx/pqiv/pqiv-9999.ebuild b/media-gfx/pqiv/pqiv-9999.ebuild
index 38325520298a95dd0ce7d6fcc665ae941e8411bc..92c15ed6806ffd6b3f37bce37b0f5e1e960387e5 100644 (file)
--- a/media-gfx/pqiv/pqiv-9999.ebuild
+++ b/media-gfx/pqiv/pqiv-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -20,7 +20,7 @@ SLOT="0"
 IUSE="archive ffmpeg imagemagick kernel_linux libav pdf postscript webp"
 
 RDEPEND="
-       >=dev-libs/glib-2.8:2
+       >=dev-libs/glib-2.32:2
        >=x11-libs/cairo-1.6
        x11-libs/gtk+:3
        archive? ( app-arch/libarchive:0= )