dev-python/tox: version bump

Package-Manager: Portage-2.3.6, Repoman-2.3.2

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 105f3bc7748b226aeaa498db8edf83f344bd5eec..2a71321655e0e86069532d41876e767c82d236ba 100644 (file)
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1 +1,2 @@
 DIST tox-2.4.1.tar.gz 113677 SHA256 6673571a3c4b1561b564e2b1cce55bddfb4f3efdb387ba4eb0a3688bbe2496db SHA512 f636b08a9f386ad20058581ca03cae0a259fe3432d3d4bd9a5117c30cb2f2c2d35d7fd499057654cd55d86c172456101f82b320d120f67afd8669a74fa63b860 WHIRLPOOL 7386f0b30e50dd8d89e05871491347849ee18b11cc89b0871cbe2719b2a75b140afa65c5d4b5e7c4266f33f89c7a36e24aa52036ae8845d5ad70279d417abb2d
+DIST tox-2.7.0.tar.gz 120139 SHA256 9c3bdc06fe411d24015e8bbbab9d03dc5243a970154496aac13f9283682435f9 SHA512 96088a9f77e8b994d920a8c9907a0fa50d5e0fe918e5a67673d4c30810642be2872283810d1d8b5ae9cc311605236b64343248485c4d4067b54c7b6d9f31a4b4 WHIRLPOOL ed77717cfead6e98ff31fb773b31bcf55bb8c4892c281aae68d10459f4ffe0c386d5adc7e1dcaacfffe2a17e005231d1dc51f3ddb3900cb09547eba6ed444628

diff --git a/dev-python/tox/tox-2.7.0.ebuild b/dev-python/tox/tox-2.7.0.ebuild
new file mode 100644 (file)
index 0000000..2b1b24d
--- /dev/null
+++ b/dev-python/tox/tox-2.7.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="http://tox.testrun.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="doc test"
+
+# tests need internet
+RESTRICT="test"
+
+RDEPEND="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       >=dev-python/virtualenv-1.11.2[${PYTHON_USEDEP}]
+       dev-python/pluggy[${PYTHON_USEDEP}]
+       dev-python/pip[${PYTHON_USEDEP}]
+       >=dev-python/py-1.4.17[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+       doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+       test? ( >=dev-python/pytest-2.3.5[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+       # remove intersphinx stuff
+       sed -i -e "s/'sphinx.ext.intersphinx',//" doc/conf.py || die
+       distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+       if use doc; then
+               esetup.py build_sphinx
+               HTML_DOCS=( "${S}"/doc/build/html/. )
+       fi
+}
+
+python_test() {
+       esetup.py test || die "Testsuite failed under ${EPYTHON}"
+}