dev-python/uranium: version bump to 3.4.1

Bug: https://bugs.gentoo.org/660884
Package-Manager: Portage-2.3.42, Repoman-2.3.9

diff --git a/dev-python/uranium/Manifest b/dev-python/uranium/Manifest
index 5537897103509c6fbfbb74ed3e97d96225691061..c401c50d6199723fedcbb894a15bc5dd0dbde3a0 100644 (file)
--- a/dev-python/uranium/Manifest
+++ b/dev-python/uranium/Manifest
@@ -1 +1,2 @@
 DIST uranium-3.3.0.tar.gz 906093 BLAKE2B d41608170da64f93d6149e76cc28fa476e439f6b291bc667f8b562dbcde047f234aa77cfa52b73420f286b926ef05ef50df8fd74722fc81dd3fe94b407bee7f4 SHA512 48de8ecf100f6bfbaa6b3bc6562fef25991ad07375f3d8f752f130b44c2e4728b2979f99de23570cd46367d868bb7139dfd9d73a7d3755d2141edc1fd46939b3
+DIST uranium-3.4.1.tar.gz 646742 BLAKE2B eb65d5a35b3c63cfb069f6c1077a91b7aa10517dd7fe6938b639f1229e61c5c6aa892447cd9d5851df46808f01f237820811b4358a235c50a89f2333df3418ef SHA512 59e0a605f3d898765bb670104cabb7fb1471061934900e63b54c1a07219970e07414a3983e96a577f5986302779b7acedc8e0ef0da3756dceefc0170ec80645b

diff --git a/dev-python/uranium/uranium-3.4.1.ebuild b/dev-python/uranium/uranium-3.4.1.ebuild
new file mode 100644 (file)
index 0000000..ea92647
--- /dev/null
+++ b/dev-python/uranium/uranium-3.4.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{5,6} )
+
+inherit cmake-utils python-single-r1
+
+MY_PN="Uranium"
+
+DESCRIPTION="A Python framework for building 3D printing related applications"
+HOMEPAGE="https://github.com/Ultimaker/Uranium"
+SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+       ~dev-libs/libarcus-${PV}:=[python,${PYTHON_USEDEP}]
+       <dev-python/PyQt5-5.10[${PYTHON_USEDEP},declarative,network,svg]
+       dev-python/numpy[${PYTHON_USEDEP}]
+       >=sci-libs/scipy-1.1[${PYTHON_USEDEP}]
+       dev-qt/qtquickcontrols:5
+       dev-qt/qtquickcontrols2:5"
+
+DEPEND="${RDEPEND}
+       sys-devel/gettext
+       doc? ( app-doc/doxygen )
+       test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+DOCS=( README.md )
+
+PATCHES=( "${FILESDIR}/${PN}-3.3.0-fix-install-paths.patch" )
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_configure() {
+       local mycmakeargs=(
+               -DPYTHON_SITE_PACKAGES_DIR="$(python_get_sitedir)" )
+       cmake-utils_src_configure
+}
+
+src_compile() {
+       cmake-utils_src_compile
+       if use doc; then
+               cmake-utils_src_compile doc
+               DOCS+=( html )
+       fi
+}
+
+src_test() {
+       emake -C "${BUILD_DIR}" tests
+}
+
+src_install() {
+       cmake-utils_src_install
+       python_optimize "${D}usr/$(get_libdir)"
+}