Update BMP preproc to work with new zpaq.

Package-Manager: portage-2.2.0_alpha51_p9/cvs/Linux x86_64

diff --git a/app-arch/zpaq-extras/ChangeLog b/app-arch/zpaq-extras/ChangeLog
index c747a02fb10b12e6bb67a61f99ccb4ffebc90301..dd914aaa0e539ce80587124d39a975d88b659b34 100644 (file)
--- a/app-arch/zpaq-extras/ChangeLog
+++ b/app-arch/zpaq-extras/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-arch/zpaq-extras
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/zpaq-extras/ChangeLog,v 1.3 2011/01/06 16:10:21 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/zpaq-extras/ChangeLog,v 1.4 2011/08/25 12:14:38 mgorny Exp $
+
+*zpaq-extras-1 (25 Aug 2011)
+
+  25 Aug 2011; Michał Górny <mgorny@gentoo.org>
+  zpaq-extras-0_p20110106.ebuild, +zpaq-extras-1.ebuild:
+  Update BMP preproc to work with new zpaq.
 
 *zpaq-extras-0_p20110106 (06 Jan 2011)
 

diff --git a/app-arch/zpaq-extras/zpaq-extras-0_p20110106.ebuild b/app-arch/zpaq-extras/zpaq-extras-0_p20110106.ebuild
index c6684749dcc304ea52aee92373999dc594141756..eeb03956ae8044d2fc1bab9dbe9761afd37dd0e9 100644 (file)
--- a/app-arch/zpaq-extras/zpaq-extras-0_p20110106.ebuild
+++ b/app-arch/zpaq-extras/zpaq-extras-0_p20110106.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/zpaq-extras/zpaq-extras-0_p20110106.ebuild,v 1.1 2011/01/06 16:10:21 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/zpaq-extras/zpaq-extras-0_p20110106.ebuild,v 1.2 2011/08/25 12:14:38 mgorny Exp $
 
 EAPI=3
 inherit base toolchain-funcs
@@ -23,7 +23,8 @@ KEYWORDS="~amd64"
 IUSE=""
 
 DEPEND="app-arch/unzip"
-RDEPEND="!<app-arch/zpaq-2.03"
+RDEPEND="!<app-arch/zpaq-2.03
+       <app-arch/zpaq-3"
 
 S=${WORKDIR}
 

diff --git a/app-arch/zpaq-extras/zpaq-extras-1.ebuild b/app-arch/zpaq-extras/zpaq-extras-1.ebuild
new file mode 100644 (file)
index 0000000..667750a
--- /dev/null
+++ b/app-arch/zpaq-extras/zpaq-extras-1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/zpaq-extras/zpaq-extras-1.ebuild,v 1.1 2011/08/25 12:14:38 mgorny Exp $
+
+EAPI=3
+inherit base toolchain-funcs
+
+DESCRIPTION="A set of additional compression profiles for app-arch/zpaq"
+HOMEPAGE="http://mattmahoney.net/dc/zpaq.html"
+SRC_URI="http://mattmahoney.net/dc/bwt_j3.zip
+       http://mattmahoney.net/dc/bwt_slowmode1.zip
+       http://mattmahoney.net/dc/exe_j1.zip
+       http://mattmahoney.net/dc/jpg_test2.zip
+       http://mattmahoney.net/dc/min.zip
+       http://mattmahoney.net/dc/fast.cfg -> zpaq-fast.cfg
+       http://mattmahoney.net/dc/mid.cfg -> zpaq-mid.cfg
+       http://mattmahoney.net/dc/max.cfg -> zpaq-max.cfg
+       http://mattmahoney.net/dc/bmp_j4a.zip"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+DEPEND="app-arch/unzip"
+RDEPEND=">=app-arch/zpaq-3"
+
+S=${WORKDIR}
+
+src_unpack() {
+       local x
+       for x in ${A}; do
+               if [[ ${x} == *.cfg ]]; then
+                       cp "${DISTDIR}"/${x} ${x#zpaq-} || die
+               fi
+       done
+
+       default
+}
+
+src_configure() {
+       sed \
+               -e "/^pcomp zpaq/s:-m:-m${EPREFIX}/usr/share/zpaq/:" \
+               -e "s:^pcomp zpaq:pcomp ${EPREFIX}/usr/bin/zpaq:" \
+               -e "s:^pcomp \([^/]\):pcomp ${EPREFIX}/usr/libexec/zpaq/\1:" \
+               -i *.cfg || die
+
+       local sources=( *.cpp )
+       # (the following assignment flattens the array)
+       progs=${sources[@]%.cpp}
+}
+
+src_compile() {
+       tc-export CXX
+       emake ${progs} || die
+}
+
+src_install() {
+       exeinto /usr/libexec/zpaq
+       doexe ${progs} || die
+
+       insinto /usr/share/zpaq
+       doins *.cfg || die
+}