dev-libs/libdazzle: New package with fancy features for gtk+

Mainly used by dev-util/gnome-builder, but useful for any
application wanting to use the provided GTK+ widgets and
GObject utilities.

Package-Manager: Portage-2.3.48, Repoman-2.3.10

diff --git a/dev-libs/libdazzle/Manifest b/dev-libs/libdazzle/Manifest
new file mode 100644 (file)
index 0000000..4509c18
--- /dev/null
+++ b/dev-libs/libdazzle/Manifest
@@ -0,0 +1 @@
+DIST libdazzle-3.28.5.tar.xz 422792 BLAKE2B 65b994798c2f9c7ec0d5ec5b3506896ba3fe09e8e563f1c03246684837a876d0918763f8589deccfc1477071434acda56973097904c3ad5469aa4374a56d1914 SHA512 e4616994226a7e755913343487a2850030dc13816c94dd0de166bb617a001097f6b849fa45ee546e75a15ad3357bd5a61a0caf436c4e3656eaa3480ed4b7f903

diff --git a/dev-libs/libdazzle/libdazzle-3.28.5.ebuild b/dev-libs/libdazzle/libdazzle-3.28.5.ebuild
new file mode 100644 (file)
index 0000000..9dddb0f
--- /dev/null
+++ b/dev-libs/libdazzle/libdazzle-3.28.5.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome.org meson xdg vala virtualx
+
+DESCRIPTION="Experimental new features for GTK+ and GLib"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libdazzle"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="gtk-doc +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+       >=dev-libs/glib-2.56.0:2
+       x11-libs/gtk+:3[introspection?]
+       introspection? ( dev-libs/gobject-introspection:= )
+"
+# libxml2 required for glib-compile-resources; glib-utils for glib-mkenums
+DEPEND="${RDEPEND}
+       vala? ( $(vala_depend) )
+       dev-libs/libxml2:2
+       dev-util/glib-utils
+       virtual/pkgconfig
+       gtk-doc? ( dev-util/gtk-doc )
+"
+
+src_prepare() {
+       use vala && vala_src_prepare
+       xdg_src_prepare
+}
+
+src_configure() {
+       local emesonargs=(
+               -Denable_tracing=false # extra trace debugging that would make things slower
+               -Denable_profiling=false # -pg passing
+               # -Denable_rdtscp=false # TODO: CPU_FLAGS_X86 for it?
+               -Denable_tools=true # /usr/bin/dazzle-list-counters
+               $(meson_use introspection with_introspection)
+               $(meson_use vala with_vapi)
+               $(meson_use gtk-doc enable_gtk_doc)
+               $(meson_use test enable_tests)
+       )
+       meson_src_configure
+}
+
+src_test() {
+       virtx meson_src_test
+}

diff --git a/dev-libs/libdazzle/metadata.xml b/dev-libs/libdazzle/metadata.xml
new file mode 100644 (file)
index 0000000..ccb7f7e
--- /dev/null
+++ b/dev-libs/libdazzle/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+       <maintainer type="project">
+               <email>gnome@gentoo.org</email>
+               <name>Gentoo GNOME Desktop</name>
+       </maintainer>
+       <longdescription>libdazzle is a collection of fancy features for GLib and Gtk+ that aren't quite
+               ready or generic enough for use inside those libraries. This is often a proving
+               ground for new widget prototypes. Applications such as Builder tend to drive
+               development of this project.</longdescription>
+</pkgmetadata>