dev-util/include-what-you-use: bump up to 5.0, bug #647648

Reported-by: Daniel M. Weeks
Closes: https://bugs.gentoo.org/647648
Package-Manager: Portage-2.3.24, Repoman-2.3.6

diff --git a/dev-util/include-what-you-use/Manifest b/dev-util/include-what-you-use/Manifest
index fc718194e5573231affd12b2836c760b0dd619be..dac209261eeb285921ff5ff2d53fa28b5a757ccf 100644 (file)
--- a/dev-util/include-what-you-use/Manifest
+++ b/dev-util/include-what-you-use/Manifest
@@ -1,2 +1,3 @@
 DIST include-what-you-use-3.9.src.tar.gz 446773 BLAKE2B 6b8e66e7ace440ff793c07fb3a4c3db95418f213c629b119fff315559bb581a04b864f5a8cf2eed2221dca84af23fb7ae0c3b3a2c4a59af88bf1e656951f5e8e SHA512 dd7990fa4112ddb0434807efd9dcf0f77bbecaa61eab51be24428f8e45b9321c7647a979278f3f1266ba9be05c6f1de536fc084613d38638b795248001ce4b44
 DIST include-what-you-use-4.0.src.tar.gz 437340 BLAKE2B 744f7893169a637636107e23cae356db7f12aa01fefd39626600b3fa3dbd77688503e7332a2dbc673339145692625fd8fa3f10e0d405a77e2d5586e6bfeb0378 SHA512 c96b78ec8f8289bfd7830acaf533aea0077bb36311d3b8bb7f31464c1b3a5b3f353b24e81ffc581811b4083d3b5959e4e947e3a3d16cb7c77de00b05b9972a90
+DIST include-what-you-use-5.0.src.tar.gz 439081 BLAKE2B 85246aa5333a073bb195b873d7bfe084a56c343cece92322706717ce699bcd75b737203858277202791ec0eb91f560b06a371e902cb175cdb2858562a4830e74 SHA512 9d4a9717a3a3f6752f8bdd1392b6d7a5e8b8dc277ef46a50f24185a089360380e1da92a61fd150598843f5c24cff03e74bc674e57579960d977acde755e34c52

diff --git a/dev-util/include-what-you-use/include-what-you-use-5.0.ebuild b/dev-util/include-what-you-use/include-what-you-use-5.0.ebuild
new file mode 100644 (file)
index 0000000..92dc8c8
--- /dev/null
+++ b/dev-util/include-what-you-use/include-what-you-use-5.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit cmake-utils flag-o-matic llvm python-single-r1
+
+DESCRIPTION="Find unused include directives in C/C++ programs"
+HOMEPAGE="https://include-what-you-use.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/clang_${PV}.tar.gz -> ${P}.src.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+LLVM_MAX_SLOT=5
+
+RDEPEND="sys-devel/llvm:${LLVM_MAX_SLOT}
+       sys-devel/clang:${LLVM_MAX_SLOT}
+       ${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+S=${WORKDIR}/${PN}-clang_${PV}
+
+pkg_setup() {
+       llvm_pkg_setup
+       python-single-r1_pkg_setup
+}
+
+src_prepare() {
+       cmake-utils_src_prepare
+       python_fix_shebang .
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DIWYU_LLVM_INCLUDE_PATH=$(llvm-config --includedir)
+               -DIWYU_LLVM_LIB_PATH=$(llvm-config --libdir)
+
+               # Note [llvm install path]
+               # Unfortunately all binaries using clang driver
+               # have to reside at the same path depth as
+               # 'clang' binary itself. See bug #625972
+               # Thus as a hack we install it to the same directory
+               # as llvm/clang itself.
+               -DCMAKE_INSTALL_PREFIX="$(get_llvm_prefix "${LLVM_MAX_SLOT}")"
+       )
+       cmake-utils_src_configure
+}
+
+src_test() {
+       "${EPYTHON}" run_iwyu_tests.py
+}