lxqt-base/lxqt-session: version bump to 0.14.1

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/lxqt-base/lxqt-session/Manifest b/lxqt-base/lxqt-session/Manifest
index c9909c2788990448e6052601fb765ab447b853c3..e8ef92078b907540a388b9d6aee6d3099237e8a9 100644 (file)
--- a/lxqt-base/lxqt-session/Manifest
+++ b/lxqt-base/lxqt-session/Manifest
@@ -1 +1,2 @@
 DIST lxqt-session-0.13.0.tar.xz 135240 BLAKE2B 6856b6a14e635408ec86d612ebd549431afba74d990c23977ef8e14cdc043b039888ff5e0a67f265ff4085d936f5fc3d655a4bfcb94f342bef375d597d05de82 SHA512 3ab6161ee75340f823ec82d20ead9eacf7441fd675e2f8a295fc301187e027013c8a2a4e7ca1262795e9b07d3231dbab032363cadde3bf334865260142529316
+DIST lxqt-session-0.14.1.tar.xz 178600 BLAKE2B a4f0f096b994ea409e47d364bbde93bb66bfb4b5fb157ec1acb78a3055584dd31772ca2ed6a6592940e6fb578bbca3d0499f6eaa9775f84ce9703c39b0fc0bf3 SHA512 9274564f3eabe33744bbe8555b1177d8ff6f241f5849bef29f0bb344f506e590e1deab87bf2fdeb867872ebaa0262cda0400f16179951fd66fbcb4d9f7358c4c

diff --git a/lxqt-base/lxqt-session/lxqt-session-0.14.1.ebuild b/lxqt-base/lxqt-session/lxqt-session-0.14.1.ebuild
new file mode 100644 (file)
index 0000000..91df667
--- /dev/null
+++ b/lxqt-base/lxqt-session/lxqt-session-0.14.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="LXQT session manager"
+HOMEPAGE="https://lxqt.org/"
+
+MY_PV="$(ver_cut 1-2)*"
+
+if [[ ${PV} = *9999* ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+       SRC_URI="https://downloads.lxqt.org/downloads/${PN}/${PV}/${P}.tar.xz"
+       KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+IUSE="+themes +udev"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+
+BDEPEND="
+       dev-qt/linguist-tools:5
+       >=dev-util/lxqt-build-tools-0.6.0
+"
+DEPEND="
+       >=dev-libs/libqtxdg-3.3.1
+       dev-qt/qtcore:5
+       dev-qt/qtdbus:5
+       dev-qt/qtgui:5
+       dev-qt/qtwidgets:5
+       dev-qt/qtx11extras:5
+       kde-frameworks/kwindowsystem:5[X]
+       =lxqt-base/liblxqt-${MY_PV}
+       x11-libs/libX11
+       x11-misc/xdg-user-dirs
+       themes? ( =x11-themes/lxqt-themes-${MY_PV} )
+       udev? ( virtual/libudev )
+"
+RDEPEND="${DEPEND}
+       !lxqt-base/lxqt-l10n
+"
+
+src_configure() {
+       local mycmakeargs=(
+               -DWITH_LIBUDEV=$(usex udev)
+       )
+       cmake-utils_src_configure
+}
+
+src_install(){
+       cmake-utils_src_install
+       doman lxqt-config-session/man/*.1 lxqt-session/man/*.1
+
+       echo XDG_CONFIG_DIRS=\"${EPREFIX}/usr/share\" >> 91lxqt-config-dir
+       doenvd 91lxqt-config-dir
+}