dev-libs/liblognorm: bump to v2.0.6

Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>

diff --git a/dev-libs/liblognorm/Manifest b/dev-libs/liblognorm/Manifest
index be5c55b0d9752f01d1294785881a2beeafbce242..f3c4465da4bfe4992ac68c506d49d83a23f9d03f 100644 (file)
--- a/dev-libs/liblognorm/Manifest
+++ b/dev-libs/liblognorm/Manifest
@@ -1 +1,2 @@
 DIST liblognorm-2.0.5.tar.gz 667709 BLAKE2B 9f2a774c2378caa460a1f11e21570e719f83e782c5731a35921099b1b31397495ea2a4baebd489d186526eb2d011f2ab30d971713a8083c1ae02168d3f632ce8 SHA512 2b36fabfa8b751127d47f307833414d339ae43bad5b687ce6ac42a961021f9a515703ca0c4808e098ef49be3a943abdbf307f90995a2331c6e266167ef041d00
+DIST liblognorm-2.0.6.tar.gz 666712 BLAKE2B 4c3e46fbd9a3eaf6c429872d30c0fe93f1255dbf3cc14efc82ab94d70ef45c5560c50644e0e23dc63777ddbc405d0f3fb911975d06fd6f6cdee6f7b98ff10b74 SHA512 0b4ee55eb54920dd096fdd6d6dcc2263bc52e74442d86503bfebf26b31492a8c1b67cb3b709ecc8b96cc53252151515719027306b2b6f7ba3404adc5a48cf125

diff --git a/dev-libs/liblognorm/liblognorm-2.0.6.ebuild b/dev-libs/liblognorm/liblognorm-2.0.6.ebuild
new file mode 100644 (file)
index 0000000..8351fc5
--- /dev/null
+++ b/dev-libs/liblognorm/liblognorm-2.0.6.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit autotools
+
+DESCRIPTION="Fast samples-based log normalization library"
+HOMEPAGE="http://www.liblognorm.com"
+
+if [[ ${PV} == "9999" ]]; then
+       EGIT_REPO_URI="https://github.com/rsyslog/${PN}.git"
+
+       inherit git-r3
+else
+       SRC_URI="http://www.liblognorm.com/files/download/${P}.tar.gz"
+       KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~x86 ~amd64-linux"
+fi
+
+LICENSE="LGPL-2.1 Apache-2.0"
+SLOT="0/5.1.0"
+IUSE="debug doc static-libs test"
+
+RDEPEND="
+       >=dev-libs/libestr-0.1.3
+       >=dev-libs/libfastjson-0.99.2:=
+"
+
+DEPEND="
+       ${RDEPEND}
+       >=sys-devel/autoconf-archive-2015.02.04
+       virtual/pkgconfig
+       doc? ( >=dev-python/sphinx-1.2.2 )
+"
+
+DOCS=( ChangeLog )
+
+src_prepare() {
+       default
+
+       eautoreconf
+}
+
+src_configure() {
+       # regexp disabled due to https://github.com/rsyslog/liblognorm/issues/143
+       local myeconfargs=(
+               --enable-compile-warnings=yes
+               --disable-Werror
+               $(use_enable doc docs)
+               $(use_enable test testbench)
+               $(use_enable debug)
+               $(use_enable static-libs static)
+               --disable-regexp
+       )
+
+       econf "${myeconfargs[@]}"
+}
+
+src_test() {
+       # When adding new tests via patches we have to make them executable
+       einfo "Adjusting permissions of test scripts ..."
+       find "${S}"/tests -type f -name '*.sh' \! -perm -111 -exec chmod a+x '{}' \; || \
+               die "Failed to adjust test scripts permission"
+
+       emake --jobs 1 check
+}
+
+src_install() {
+       default
+
+       find "${ED}"usr/lib* -name '*.la' -delete || die
+}