dev-util/pkgcheck: version bump to 0.5.4

diff --git a/dev-util/pkgcheck/Manifest b/dev-util/pkgcheck/Manifest
index 0de858ca3281be82682054c485a4dc1814e87a6c..e834ea098de31fd36166ce257292cab2a46e3d6f 100644 (file)
--- a/dev-util/pkgcheck/Manifest
+++ b/dev-util/pkgcheck/Manifest
@@ -1 +1,2 @@
 DIST pkgcheck-0.5.3.tar.gz 80896 SHA256 f062626d33346c321b11cd9e7041a22fa9fc00dd5daeca00e588467aa21936e1 SHA512 39804112b70bb90b655754b78d87a23906b749622083534dda1cb7b7e381c61f95c41c02fbfc6f8dea075bd3665cfda93f565c5d896779d5746ac71b74878df9 WHIRLPOOL 425da2fececa661584dbf5a3c602b855130eea7db97ceaee4c124059ba04944eb8d13d5899951e31127203697c3849e1bb00b5ad6e50210da7e48a22ff5ae244
+DIST pkgcheck-0.5.4.tar.gz 95354 SHA256 43e15ecb2cf384d39a587ad31b7ad3ee5915c517a1e39a4cb6bc6eb132e69bab SHA512 3c196ce170bb01f0a9f15caa8557e30cad8e088ab9bc733ac754e9c5f6d9078a70a4d14649ee5342848cc170f3c34d7575b35872c5d1a5693fb7aad207727b1b WHIRLPOOL 116b2de4d7e6569f61aa5c36a64e898cc11c2921c01572780d67bcec3db497adcfceaf54911011233160679841ac63de48741128cfbe565a08a95dd6ca0dc0d2

diff --git a/dev-util/pkgcheck/pkgcheck-0.5.4.ebuild b/dev-util/pkgcheck/pkgcheck-0.5.4.ebuild
new file mode 100644 (file)
index 0000000..6a4fce0
--- /dev/null
+++ b/dev-util/pkgcheck/pkgcheck-0.5.4.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+DISTUTILS_IN_SOURCE_BUILD=1
+inherit distutils-r1
+
+if [[ ${PV} == *9999 ]] ; then
+       EGIT_REPO_URI="https://github.com/pkgcore/pkgcheck.git"
+       inherit git-r3
+else
+       KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+       SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+fi
+
+DESCRIPTION="pkgcore-based QA utility"
+HOMEPAGE="https://github.com/pkgcore/pkgcheck"
+
+LICENSE="|| ( BSD GPL-2 )"
+SLOT="0"
+
+if [[ ${PV} == *9999 ]]; then
+       RDEPEND="
+               =dev-python/snakeoil-9999[${PYTHON_USEDEP}]
+               =sys-apps/pkgcore-9999[${PYTHON_USEDEP}]"
+else
+       RDEPEND="
+               >=dev-python/snakeoil-0.7.2[${PYTHON_USEDEP}]
+               >=sys-apps/pkgcore-0.9.5[${PYTHON_USEDEP}]"
+fi
+RDEPEND+=" dev-python/lxml[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+       dev-python/setuptools[${PYTHON_USEDEP}]"
+[[ ${PV} == *9999 ]] && DEPEND+=" dev-python/sphinx[${PYTHON_USEDEP}]"
+
+pkg_setup() {
+       # disable snakeoil 2to3 caching...
+       unset PY2TO3_CACHEDIR
+}
+
+python_compile_all() {
+       esetup.py build_man
+}
+
+python_test() {
+       esetup.py test
+}
+
+python_install_all() {
+       local DOCS=( AUTHORS NEWS.rst )
+       distutils-r1_python_install install_man
+       distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+       python_foreach_impl pplugincache pkgcheck.plugins
+}

diff --git a/dev-util/pkgcheck/pkgcheck-9999.ebuild b/dev-util/pkgcheck/pkgcheck-9999.ebuild
index 7e1fffdd38abab26285bdb13f2aba679f1e667d8..6a4fce0ea52428eba65173fde5771ebb4cf6abd0 100644 (file)
--- a/dev-util/pkgcheck/pkgcheck-9999.ebuild
+++ b/dev-util/pkgcheck/pkgcheck-9999.ebuild
@@ -11,7 +11,7 @@ if [[ ${PV} == *9999 ]] ; then
        inherit git-r3
 else
        KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
-       SRC_URI="https://github.com/pkgcore/${PN}/releases/download/v${PV}/${P}.tar.gz"
+       SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 fi
 
 DESCRIPTION="pkgcore-based QA utility"
@@ -20,11 +20,16 @@ HOMEPAGE="https://github.com/pkgcore/pkgcheck"
 LICENSE="|| ( BSD GPL-2 )"
 SLOT="0"
 
-RDEPEND="
-       =sys-apps/pkgcore-9999[${PYTHON_USEDEP}]
-       =dev-python/snakeoil-9999[${PYTHON_USEDEP}]
-       dev-python/lxml[${PYTHON_USEDEP}]
-"
+if [[ ${PV} == *9999 ]]; then
+       RDEPEND="
+               =dev-python/snakeoil-9999[${PYTHON_USEDEP}]
+               =sys-apps/pkgcore-9999[${PYTHON_USEDEP}]"
+else
+       RDEPEND="
+               >=dev-python/snakeoil-0.7.2[${PYTHON_USEDEP}]
+               >=sys-apps/pkgcore-0.9.5[${PYTHON_USEDEP}]"
+fi
+RDEPEND+=" dev-python/lxml[${PYTHON_USEDEP}]"
 DEPEND="${RDEPEND}
        dev-python/setuptools[${PYTHON_USEDEP}]"
 [[ ${PV} == *9999 ]] && DEPEND+=" dev-python/sphinx[${PYTHON_USEDEP}]"