gui-apps/swaylock: 1.5 bump

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

diff --git a/gui-apps/swaylock/Manifest b/gui-apps/swaylock/Manifest
index 30978a155d039e4d8861e6ced87d42fa1ccc3da1..c79d922f5af2240b3c15b816bb689aa7300adb99 100644 (file)
--- a/gui-apps/swaylock/Manifest
+++ b/gui-apps/swaylock/Manifest
@@ -1,2 +1,3 @@
 DIST swaylock-1.3.tar.gz 32848 BLAKE2B 81ed50839bcb0139e7fc2081bd37e738f3e6ef23e96a5108d1acf56cc3425285f7382576a54201f1bf188883b1da06492074c091877af13832c0140e4e6099fd SHA512 723d758d76f076f3f1539ea0d651f6ad2562659c72eef7e895d7827a0be21db663652fe4ce2609065aff45ff20230879599868cff327ab52b896330ca04d78c4
 DIST swaylock-1.4.tar.gz 34288 BLAKE2B 6b2c8764fd605b04843c254e776f7174caedf4f0dbc85cbd9b5cc10762eed5694ac2fdaa0393a630afc374980f0d6530104119505f034d65af37d738ab1a30fc SHA512 5068b5f97e3094c511deda553f363a71f655b16e6533ef8f82befcd3b9027a55de81f143eb95e60cf4dbe4cecdc49906285bd6a0e6d51eb3b2807d0101581809
+DIST swaylock-1.5.tar.gz 35350 BLAKE2B c68073d6154842c2cdb99836bda991560605f6ede66c6124986c3395575a4e2c22d59a837a09033d1632b61628e45b18b3ee5ca198bafe4fbd8f429cb0401eda SHA512 16dd9b912ca702849290cf18d91ffbd64a70118cc284982a84b567c4974fd4590b12707c0aae1fcda7ccd1caa7880f342c633b9345bd795c36702916696d1f67

diff --git a/gui-apps/swaylock/swaylock-1.5.ebuild b/gui-apps/swaylock/swaylock-1.5.ebuild
new file mode 100644 (file)
index 0000000..1181380
--- /dev/null
+++ b/gui-apps/swaylock/swaylock-1.5.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit fcaps meson
+
+DESCRIPTION="Screen locker for Wayland"
+HOMEPAGE="https://github.com/swaywm/swaylock"
+
+if [[ ${PV} == 9999 ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+else
+       SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="fish-completion +gdk-pixbuf +man +pam zsh-completion"
+
+DEPEND="
+       dev-libs/wayland
+       x11-libs/cairo
+       x11-libs/libxkbcommon
+       gdk-pixbuf? ( x11-libs/gdk-pixbuf:2 )
+       pam? ( sys-libs/pam )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+       >=dev-libs/wayland-protocols-1.14
+       virtual/pkgconfig
+       man? ( app-text/scdoc )
+"
+
+src_configure() {
+       local emesonargs=(
+               -Dman-pages=$(usex man enabled disabled)
+               -Dpam=$(usex pam enabled disabled)
+               -Dgdk-pixbuf=$(usex gdk-pixbuf enabled disabled)
+               $(meson_use fish-completion fish-completions)
+               $(meson_use zsh-completion zsh-completions)
+               "-Dbash-completions=true"
+               "-Dwerror=false"
+       )
+       if [[ ${PV} != 9999 ]]; then
+               emesonargs+=("-Dswaylock-version=${PV}")
+       fi
+
+       meson_src_configure
+}
+
+pkg_postinst() {
+       if ! use pam; then
+               fcaps cap_sys_admin usr/bin/swaylock
+       fi
+}

diff --git a/gui-apps/swaylock/swaylock-9999.ebuild b/gui-apps/swaylock/swaylock-9999.ebuild
index 32d4bd3b58d899852cc6b3d4ec4c1a382e2dabd6..11813805e31f94292851167e981cbba450c92590 100644 (file)
--- a/gui-apps/swaylock/swaylock-9999.ebuild
+++ b/gui-apps/swaylock/swaylock-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -27,10 +27,7 @@ DEPEND="
        gdk-pixbuf? ( x11-libs/gdk-pixbuf:2 )
        pam? ( sys-libs/pam )
 "
-RDEPEND="
-       ${DEPEND}
-       !<=gui-wm/sway-1.0_beta2[swaylock]
-"
+RDEPEND="${DEPEND}"
 BDEPEND="
        >=dev-libs/wayland-protocols-1.14
        virtual/pkgconfig