dev-java/java-config: Remove java-config-wrapper dependency, EAPI bump

java-config-wrapper is very obsolete but we have relied on it because
it installs the java-config symlink. We don't have time to do a
java-config bump yet but we can easily install the symlink
here. Addresses bug #504124.

Package-Manager: portage-2.2.27

diff --git a/dev-java/java-config/java-config-2.2.0-r1.ebuild b/dev-java/java-config/java-config-2.2.0-r1.ebuild
new file mode 100644 (file)
index 0000000..171c3ed
--- /dev/null
+++ b/dev-java/java-config/java-config-2.2.0-r1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+# jython depends on java-config, so don't add it or things will break
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="Java environment configuration query tool"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Java"
+SRC_URI="https://dev.gentoo.org/~sera/distfiles/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE=""
+
+# baselayout-java is added as a dep till it can be added to eclass.
+RDEPEND="
+       !dev-java/java-config-wrapper
+       sys-apps/baselayout-java
+       sys-apps/portage"
+
+python_install_all() {
+       distutils-r1_python_install_all
+
+       # This replaces the file installed by java-config-wrapper.
+       cp -a "${ED}/usr/bin/${PN}-2" "${ED}/usr/bin/${PN}" || die
+}
+
+python_test() {
+       esetup.py test
+}