net-libs/shairplay: fix use flags and dependencies

media-libs/libao is always required
net-dns/avahi[mdnsresponder-compat] is a build time dependency
Drop alac use flag; media-sound/alac_decoder is never used
drop tools use flag as tools are not configurable

Closes: https://bugs.gentoo.org/671410
Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Craig Andrews <candrews@gentoo.org>

diff --git a/net-libs/shairplay/shairplay-0_pre20180824-r1.ebuild b/net-libs/shairplay/shairplay-0_pre20180824-r1.ebuild
new file mode 100644 (file)
index 0000000..e8573a8
--- /dev/null
+++ b/net-libs/shairplay/shairplay-0_pre20180824-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+if [[ ${PV} == "9999" ]] ; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/juhovh/${PN}.git"
+else
+       EGIT_COMMIT="096b61ad14c90169f438e690d096e3fcf87e504e"
+       SRC_URI="https://github.com/juhovh/${PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+       S="${WORKDIR}/${PN}-${EGIT_COMMIT}"
+       KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Apple airplay and raop protocol server"
+HOMEPAGE="https://github.com/juhovh/shairplay"
+LICENSE="BSD LGPL-2.1 MIT
+       playfair? ( GPL-3+ )"
+
+SLOT="0"
+IUSE="+playfair static-libs"
+
+DEPEND="
+       net-dns/avahi[mdnsresponder-compat]
+       media-libs/libao
+"
+
+RDEPEND="
+       ${DEPEND}
+"
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+src_configure() {
+       econf \
+               $(use_with playfair) \
+               $(use_enable static-libs static)
+}
+
+src_install() {
+       default
+       find "${D}" -name '*.la' -delete || die
+}

diff --git a/net-libs/shairplay/shairplay-9999.ebuild b/net-libs/shairplay/shairplay-9999.ebuild
index f4af8a0449c90e788ec8c586656d74f30befbce2..e8573a8c12b6ef47a5628fea7c62028bd40f000c 100644 (file)
--- a/net-libs/shairplay/shairplay-9999.ebuild
+++ b/net-libs/shairplay/shairplay-9999.ebuild
@@ -21,21 +21,15 @@ LICENSE="BSD LGPL-2.1 MIT
        playfair? ( GPL-3+ )"
 
 SLOT="0"
-IUSE="alac +playfair static-libs tools"
+IUSE="+playfair static-libs"
 
 DEPEND="
-       tools? ( media-libs/libao )
+       net-dns/avahi[mdnsresponder-compat]
+       media-libs/libao
 "
 
 RDEPEND="
-       alac? (
-               media-sound/alac_decoder
-               net-libs/shairplay[tools]
-       )
-       tools? (
-               dev-libs/openssl:0=
-               net-dns/avahi[mdnsresponder-compat]
-       )
+       ${DEPEND}
 "
 
 src_prepare() {