net-misc/miniupnpd: Bump to 2.1.20191006

Signed-off-by: Michał Górny <mgorny@gentoo.org>

diff --git a/net-misc/miniupnpd/Manifest b/net-misc/miniupnpd/Manifest
index 86ae703ac63ddced2ec67d1a93faaed319eb7fa8..6bdc91e46011e5d52bfd8c17584b6b9292faa4a3 100644 (file)
--- a/net-misc/miniupnpd/Manifest
+++ b/net-misc/miniupnpd/Manifest
@@ -1,2 +1,3 @@
 DIST miniupnpd-2.1.20190902.tar.gz 240742 BLAKE2B 0b880b1e8a96c56af92726d3fe81da0a26de83861efe4dc266e287623dcac4c6bd4c4ac8d2c6ef7724c1055933d5138e7c86da5c8e3852f2022f69697505f231 SHA512 0abeb9df088ecd57909106fbb43de14d90eebd351a466477777f413f40c49bc432050bc8ea0d655d2eea0bfcedbdb97719ea2476a8bd9170ef9b74ad97217d26
 DIST miniupnpd-2.1.20190924.tar.gz 241008 BLAKE2B 392006e71ede0d18dc1dbfd13c46e591f6675fcb02828461f0afc79b4019f953f62ab95669e92cee4724ff502585420c563d555a7948b0f9d25d755efe6bdb2c SHA512 719a3ac741327691170d7e933b170dcc1399da1958d9373327b96ab5d975290d2bfa0f68d96fbb2ac4b3fb9808b50385291705cd393252263f403d43298c4031
+DIST miniupnpd-2.1.20191006.tar.gz 243255 BLAKE2B 38654cfc0238cdd413600216b01465cbecda69589249df5b6500db7e0719053dae351ab8c61d763a7586924f68b6d634266a1020084f30261442ac62fbd17a5e SHA512 5de2dc5ffb6df7b06bcb6ab8d8fbb34aa5a229a8310938e980b4caf6b957ceab104c455cebb57d7083736fde2db9569fcdf98783a36c915d362f7ff2987e3599

diff --git a/net-misc/miniupnpd/miniupnpd-2.1.20191006.ebuild b/net-misc/miniupnpd/miniupnpd-2.1.20191006.ebuild
new file mode 100644 (file)
index 0000000..2e0b60b
--- /dev/null
+++ b/net-misc/miniupnpd/miniupnpd-2.1.20191006.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="MiniUPnP IGD Daemon"
+HOMEPAGE="http://miniupnp.free.fr/"
+SRC_URI="http://miniupnp.free.fr/files/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+leasefile igd2 ipv6 nftables pcp-peer portinuse strict"
+
+RDEPEND="
+       dev-libs/gmp:0=
+       sys-apps/util-linux:=
+       dev-libs/openssl:0=
+       !nftables? (
+               >=net-firewall/iptables-1.4.6:0=[ipv6?]
+               net-libs/libnfnetlink:=
+               net-libs/libmnl:=
+       )
+       nftables? (
+               net-firewall/nftables
+               net-libs/libnftnl:=
+               net-libs/libmnl:=
+       )"
+DEPEND="${RDEPEND}
+       sys-apps/lsb-release"
+
+src_prepare() {
+       default
+
+       # Prevent overriding CFLAGS.
+       sed -i -e '/^CFLAGS =/d' Makefile.linux_nft || die
+
+       mv "Makefile.linux$(usex nftables _nft '')" Makefile || die
+
+       # Prevent gzipping manpage.
+       sed -i -e '/gzip/d' Makefile || die
+}
+
+src_configure() {
+       local -a opts
+       opts=(
+               --vendorcfg
+               $(usex igd2 '--igd2' '')
+               $(usex ipv6 '--ipv6' '')
+               $(usex leasefile '--leasefile' '')
+               $(usex portinuse '--portinuse' '')
+               $(usex pcp-peer '--pcp-peer' '')
+               $(usex strict '--strict' '')
+       )
+
+       CONFIG_OPTIONS="${opts[*]}" emake config.h
+}
+
+src_compile() {
+       # By default, it builds a bunch of unittests that are missing wrapper
+       # scripts in the tarball
+       emake CC="$(tc-getCC)" STRIP=true miniupnpd
+}
+
+src_install() {
+       emake PREFIX="${ED}" STRIP=true install
+
+       local confd_seds=()
+       if use nftables; then
+               confd_seds+=( -e 's/^iptables_scripts=/#&/' )
+       else
+               confd_seds+=( -e 's/^nftables_scripts=/#&/' )
+       fi
+       if ! use ipv6 || use nftables; then
+               confd_seds+=( -e 's/^ip6tables_scripts=/#&/' )
+       fi
+
+       newinitd "${FILESDIR}"/${PN}-init.d-r2 ${PN}
+       newconfd - ${PN} < <(sed "${confd_seds[@]}" \
+               "${FILESDIR}"/${PN}-conf.d-r2 || die)
+}
+
+pkg_postinst() {
+       elog "Please correct the external interface in the top of the two"
+       elog "scripts in /etc/miniupnpd and edit the config file in there too"
+}