dev-python/repoze-sphinx-autointerface: Fix namespace support

diff --git a/dev-python/repoze-sphinx-autointerface/repoze-sphinx-autointerface-0.7.1-r1.ebuild b/dev-python/repoze-sphinx-autointerface/repoze-sphinx-autointerface-0.7.1-r1.ebuild
new file mode 100644 (file)
index 0000000..0c7a3a5
--- /dev/null
+++ b/dev-python/repoze-sphinx-autointerface/repoze-sphinx-autointerface-0.7.1-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_4} )
+
+inherit distutils-r1
+
+MY_PN=${PN//-/.}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Sphinx extension: auto-generates API docs from Zope interfaces"
+HOMEPAGE="https://pypi.python.org/pypi/repoze.sphinx.autointerface/"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="repoze"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+       dev-python/namespace-repoze[${PYTHON_USEDEP}]
+       dev-python/sphinx[${PYTHON_USEDEP}]
+       dev-python/zope-interface[${PYTHON_USEDEP}]
+"
+DEPEND="
+       ${RDEPEND}
+       dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+S=${WORKDIR}/${MY_P}
+
+python_install() {
+       distutils-r1_python_install
+
+       # install the namespace (it's the only subpackage)
+       python_moduleinto repoze/sphinx
+       python_domodule repoze/sphinx/__init__.py
+}
+
+python_install_all() {
+       distutils-r1_python_install_all
+
+       find "${D}" -name '*.pth' -delete || die
+}