dev-util/glade: version bump 3.20.0 → 3.20.2

Package-Manager: Portage-2.3.19, Repoman-2.3.6

diff --git a/dev-util/glade/Manifest b/dev-util/glade/Manifest
index a35aa5f5ee45b4421963db3a817c822c27876037..66524da909cb2873c763c7633e561550301a2b41 100644 (file)
--- a/dev-util/glade/Manifest
+++ b/dev-util/glade/Manifest
@@ -1 +1,2 @@
 DIST glade-3.20.0.tar.xz 3492928 BLAKE2B bab8682ec83a98f7f405a667e9fc9ad4b0fa334e0f1f3b1ba5bd8e17af1c61c65031ebe2fe56b8321df142f5a4d8dec348793bba0fc3c195c6722d635d52a291 SHA512 58c8da3522c75470f5b42492bddd83f61d828fa2a3fb8a78d15813f6d1f1df22bd808f25ae7228bf2e821bacdcc5665b889bac3ea8364c4dac288f95e817e98a
+DIST glade-3.20.2.tar.xz 3535064 BLAKE2B 33e5e9477556ac5f645cf13658ff1eebdaf046c1bbbcf5ac528c00f9b5f76943ede8140cc6a3b73dc27ed96c363208700031306f19478ba0e9e2fbae8319f500 SHA512 45f850ed4d409aaf11153da45398e7974d7b85235bf5d5043bc11755c3e4d1201f59ed854786162a7414f0521c818982560d4e226f93625b9253dc598793118a

diff --git a/dev-util/glade/glade-3.20.2.ebuild b/dev-util/glade/glade-3.20.2.ebuild
new file mode 100644 (file)
index 0000000..2f8c73b
--- /dev/null
+++ b/dev-util/glade/glade-3.20.2.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-single-r1 versionator virtualx
+
+DESCRIPTION="A user interface designer for GTK+ and GNOME"
+HOMEPAGE="https://glade.gnome.org/"
+
+LICENSE="GPL-2+ FDL-1.1+"
+SLOT="3.10/6" # subslot = suffix of libgladeui-2.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+
+IUSE="debug +introspection python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+       dev-libs/atk[introspection?]
+       >=dev-libs/glib-2.32:2
+       >=dev-libs/libxml2-2.4.0:2
+       x11-libs/cairo:=
+       x11-libs/gdk-pixbuf:2[introspection?]
+       >=x11-libs/gtk+-3.20.0:3[introspection?]
+       x11-libs/pango[introspection?]
+       introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+       python? (
+               ${PYTHON_DEPS}
+               >=dev-python/pygobject-3.8:3[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+       app-text/docbook-xml-dtd:4.1.2
+       app-text/yelp-tools
+       dev-libs/libxslt
+       >=dev-util/gtk-doc-am-1.13
+       >=dev-util/intltool-0.41.0
+       dev-util/itstool
+       virtual/pkgconfig
+
+       dev-libs/gobject-introspection-common
+       gnome-base/gnome-common
+"
+# eautoreconf requires:
+#      dev-libs/gobject-introspection-common
+#      gnome-base/gnome-common
+
+PATCHES=(
+       # To avoid file collison with other slots, rename help module.
+       # Prevent the UI from loading glade:3's gladeui devhelp documentation.
+       "${FILESDIR}"/${PN}-3.14.1-doc-version.patch
+)
+
+pkg_setup() {
+       use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+       gnome2_src_configure \
+               --disable-static \
+               --enable-gladeui \
+               --enable-libtool-lock \
+               $(usex debug --enable-debug ' ') \
+               $(use_enable introspection) \
+               $(use_enable python)
+}
+
+src_test() {
+       virtx emake check
+}
+
+src_install() {
+       # modify Name in .desktop file to avoid confusion with other slots
+       sed -e 's:^\(Name.*=Glade\):\1 '$(get_version_component_range 1-2): \
+               -i data/glade.desktop || die "sed of data/glade.desktop failed"
+       # modify name in .devhelp2 file to avoid shadowing with glade:3 docs
+       sed -e 's:name="gladeui":name="gladeui-2":' \
+               -i doc/html/gladeui.devhelp2 || die "sed of gladeui.devhelp2 failed"
+       gnome2_src_install
+}
+
+pkg_postinst() {
+       gnome2_pkg_postinst
+       if ! has_version dev-util/devhelp ; then
+               elog "You may want to install dev-util/devhelp for integration API"
+               elog "documentation support."
+       fi
+}