dev-lang/f2c: Port to EAPI 7

Package-Manager: Portage-2.3.75, Repoman-2.3.17
Signed-off-by: David Seifert <soap@gentoo.org>

diff --git a/dev-lang/f2c/f2c-20100827-r1.ebuild b/dev-lang/f2c/f2c-20100827-r1.ebuild
new file mode 100644 (file)
index 0000000..dd624e4
--- /dev/null
+++ b/dev-lang/f2c/f2c-20100827-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DEB_PV=20100827
+DEB_PR=1
+DEB_P=${PN}_${DEB_PV}
+
+DESCRIPTION="Fortran to C converter"
+HOMEPAGE="http://www.netlib.org/f2c"
+SRC_URI="
+       mirror://debian/pool/main/${PN:0:1}/${PN}/${DEB_P}.orig.tar.gz
+       mirror://debian/pool/main/${PN:0:1}/${PN}/${DEB_P}-${DEB_PR}.debian.tar.gz"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+
+RDEPEND=">=dev-libs/libf2c-20130927-r1"
+
+S="${WORKDIR}/${PN}"
+
+PATCHES=(
+       # selective list of patches from debian
+       "${WORKDIR}"/debian/patches/0000-prequilt-tweaks.patch
+       "${WORKDIR}"/debian/patches/0002-prototype-rmdir.patch
+       "${WORKDIR}"/debian/patches/0003-struct-init-braces.patch
+       "${WORKDIR}"/debian/patches/0004-man-dash-hyphen-slash.patch
+
+       "${FILESDIR}"/${PN}-20100827-fix-buildsystem.patch
+       "${FILESDIR}"/${PN}-20100827-Wimplicit-function-declaration.patch
+)
+
+src_configure() {
+       tc-export CC
+}
+
+src_compile() {
+       emake -C src -f makefile.u f2c
+}
+
+src_install() {
+       dobin src/f2c
+
+       doman f2c.1
+       dodoc src/README src/Notice
+
+       dodoc f2c.pdf
+       newdoc "${WORKDIR}"/debian/changelog debian.changelog
+}

diff --git a/dev-lang/f2c/files/f2c-20100827-Wimplicit-function-declaration.patch b/dev-lang/f2c/files/f2c-20100827-Wimplicit-function-declaration.patch
new file mode 100644 (file)
index 0000000..901bcd5
--- /dev/null
+++ b/dev-lang/f2c/files/f2c-20100827-Wimplicit-function-declaration.patch
@@ -0,0 +1,10 @@
+--- a/src/sysdeptest.c
++++ b/src/sysdeptest.c
+@@ -2,6 +2,7 @@
+ /* presence of mkdtemp and mkstemp by whether this links without error. */
+ 
+ #include <stdio.h>
++#include <stdlib.h>
+ #include <unistd.h>
+ 
+  int

diff --git a/dev-lang/f2c/files/f2c-20100827-fix-buildsystem.patch b/dev-lang/f2c/files/f2c-20100827-fix-buildsystem.patch
new file mode 100644 (file)
index 0000000..56fbb86
--- /dev/null
+++ b/dev-lang/f2c/files/f2c-20100827-fix-buildsystem.patch
@@ -0,0 +1,28 @@
+--- a/src/makefile.u
++++ b/src/makefile.u
+@@ -1,15 +1,10 @@
+ #     Makefile for f2c, a Fortran 77 to C converter
+ 
+ .SUFFIXES: .c .o
+-CC = cc
+-CFLAGS = -O
+ SHELL = /bin/sh
+ YACC = yacc
+ YFLAGS =
+ 
+-.c.o:
+-      $(CC) -c $(CFLAGS) $*.c
+-
+ OBJECTSd = main.o init.o gram.o lex.o proc.o equiv.o data.o format.o \
+         expr.o exec.o intr.o io.o misc.o error.o mem.o names.o \
+         output.o p1output.o pread.o put.o putpcc.o vax.o formatdata.o \
+@@ -100,9 +95,6 @@
+       parse.h parse_args.c pccdefs.h pread.c proc.c put.c putpcc.c \
+       sysdep.c sysdep.h sysdeptest.c tokens usignal.h vax.c version.c xsum.c
+ 
+-xsum: xsum.c
+-      $(CC) $(CFLAGS) -o xsum xsum.c
+-
+ #Check validity of transmitted source...
+ xsum.out: xsum $b
+       ./xsum $b >xsum1.out