games-board/grhino: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: portage-2.3.0

diff --git a/games-board/grhino/grhino-0.16.1-r1.ebuild b/games-board/grhino/grhino-0.16.1-r1.ebuild
new file mode 100644 (file)
index 0000000..3d650c1
--- /dev/null
+++ b/games-board/grhino/grhino-0.16.1-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="Reversi game for GNOME, supporting the Go/Game Text Protocol"
+HOMEPAGE="http://rhino.sourceforge.net/"
+SRC_URI="mirror://sourceforge/rhino/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome gtp nls"
+
+RDEPEND="gnome? ( =gnome-base/libgnomeui-2* )
+       nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+       nls? ( sys-devel/gettext )"
+
+src_prepare() {
+       default
+
+       sed -i '/^(\|locale\|help\|omf\|icon\|)/s:@datadir@:/usr/share:' \
+               Makefile.in || die
+}
+
+src_configure() {
+       if use gnome || use gtp; then
+               econf \
+                       --localedir=/usr/share/locale \
+                       $(use_enable gnome) \
+                       $(use_enable gtp) \
+                       $(use_enable nls)
+       else
+               econf \
+                       --localedir=/usr/share/locale \
+                       --enable-gtp \
+                       --disable-gnome \
+                       $(use_enable nls)
+       fi
+}
+
+src_install() {
+       default
+       use gnome && make_desktop_entry ${PN} GRhino
+}