dev-games/tiled: version bump 1.2.0

Package-Manager: Portage-2.3.49, Repoman-2.3.11

diff --git a/dev-games/tiled/Manifest b/dev-games/tiled/Manifest
index 3e2b1fc1cf59f5606ec232b7f581f6bc1fafa177..c1738ef1ca63d9d15a85bff9c58e597ab62dc99f 100644 (file)
--- a/dev-games/tiled/Manifest
+++ b/dev-games/tiled/Manifest
@@ -1 +1,2 @@
 DIST tiled-1.1.6.tar.gz 16051699 BLAKE2B 61e33682cbd0d3045c12b20fc852ec8ae81103fc1d9818a7e17222615676dd2d3889033d6d6ba536e63e069a44aaeebeaaffb96b94a2cbcb8f1793553a466703 SHA512 d1083a938bbbd87897c5897fe79d424706e719a4319680ed907be481773daea656fc5b3230ba6b674e5ea044e22ee0044df2a07a7c91c56f9521e32b86847830
+DIST tiled-1.2.0.tar.gz 17007687 BLAKE2B 6bb5a34a19868574801a69015f6a05b299dd5b34df865cacf5d2a747a62ae731b80778fe49a432c5487cbfa3d30186dc80011cc8882cb86ac347fb35a7421cbc SHA512 9c0c151348a90344b355e9bc8a7c9d38e2203d48474e8cf496e2c08cc75f764042e4355db2827f0e3518a1c03bfbcc79be7ba643c44c50430c7ecec09fbb8563

diff --git a/dev-games/tiled/tiled-1.2.0.ebuild b/dev-games/tiled/tiled-1.2.0.ebuild
new file mode 100644 (file)
index 0000000..fb9cfda
--- /dev/null
+++ b/dev-games/tiled/tiled-1.2.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_6 )
+inherit gnome2-utils multilib python-single-r1 qmake-utils xdg
+
+DESCRIPTION="A general purpose tile map editor"
+HOMEPAGE="https://www.mapeditor.org/"
+SRC_URI="https://github.com/bjorn/tiled/archive/v${PV}/${P}.tar.gz"
+
+LICENSE="BSD BSD-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+       >=dev-qt/qtcore-5.9:5
+       >=dev-qt/qtgui-5.9:5
+       >=dev-qt/qtnetwork-5.9:5
+       >=dev-qt/qtwidgets-5.9:5
+       sys-libs/zlib
+       python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}
+       dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS COPYING NEWS.md README.md )
+
+pkg_setup() {
+       use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+       eqmake5 LIBDIR="/usr/$(get_libdir)" PREFIX="/usr" DISABLE_PYTHON_PLUGIN="$(usex !python)"
+}
+
+src_install() {
+       emake INSTALL_ROOT="${D}" install
+
+       einstalldocs
+
+       if use examples ; then
+               docompress -x /usr/share/doc/${PF}/examples
+               dodoc -r examples
+       fi
+}
+
+pkg_postinst() {
+       gnome2_icon_cache_update
+       xdg_desktop_database_update
+       xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+       gnome2_icon_cache_update
+       xdg_desktop_database_update
+       xdg_mimeinfo_database_update
+}