net-firewall/firehol: add ipset support

Package-Manager: Portage-2.3.3, Repoman-2.3.1

diff --git a/net-firewall/firehol/firehol-3.1.3-r1.ebuild b/net-firewall/firehol/firehol-3.1.3-r1.ebuild
new file mode 100644 (file)
index 0000000..99e09bd
--- /dev/null
+++ b/net-firewall/firehol/firehol-3.1.3-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils linux-info
+
+DESCRIPTION="iptables firewall generator"
+HOMEPAGE="https://github.com/firehol/firehol"
+SRC_URI="https://github.com/firehol/firehol/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc ipv6 ipset"
+KEYWORDS="~amd64 ~arm"
+
+RDEPEND="net-firewall/iptables
+       sys-apps/iproute2[-minimal,ipv6?]
+       net-misc/iputils[ipv6?]
+       net-misc/iprange
+       net-analyzer/traceroute
+       virtual/modutils
+       app-arch/gzip
+       ipset? (
+               net-firewall/ipset
+       )"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+       local KCONFIG_OPTS=" \
+               ~IP_NF_FILTER \
+               ~IP_NF_IPTABLES \
+               ~IP_NF_MANGLE \
+               ~IP_NF_TARGET_MASQUERADE
+               ~IP_NF_TARGET_REDIRECT \
+               ~IP_NF_TARGET_REJECT \
+               ~NETFILTER_XT_MATCH_LIMIT \
+               ~NETFILTER_XT_MATCH_OWNER \
+               ~NETFILTER_XT_MATCH_STATE \
+               ~NF_CONNTRACK \
+               ~NF_CONNTRACK_IPV4 \
+               ~NF_CONNTRACK_MARK \
+               ~NF_NAT \
+               ~NF_NAT_FTP \
+               ~NF_NAT_IRC \
+       "
+       linux-info_pkg_setup
+}
+
+src_configure() {
+       econf \
+               --disable-vnetbuild \
+               $(use_enable ipset update-ipsets) \
+               $(use_enable doc) \
+               $(use_enable ipv6)
+}
+
+src_install() {
+       default
+
+       newconfd "${FILESDIR}"/firehol.conf.d firehol
+       newinitd "${FILESDIR}"/firehol.initrd firehol
+       newconfd "${FILESDIR}"/fireqos.conf.d fireqos
+       newinitd "${FILESDIR}"/fireqos.initrd fireqos
+}

diff --git a/net-firewall/firehol/metadata.xml b/net-firewall/firehol/metadata.xml
index 1d39106f9483cc3a6dc437ab87dc4cb60c8ddb15..eea67008d3fac652639cedca1ebfe9c82af802dc 100644 (file)
--- a/net-firewall/firehol/metadata.xml
+++ b/net-firewall/firehol/metadata.xml
@@ -7,4 +7,9 @@
        <upstream>
                <remote-id type="sourceforge">firehol</remote-id>
        </upstream>
+       <use>
+               <flag name="ipset">
+                       Use <pkg>net-firewall/ipset</pkg>.
+               </flag>
+       </use>
 </pkgmetadata>