net-mail/eps: EAPI bump, bug 605728

Package-Manager: Portage-2.3.6, Repoman-2.3.2

diff --git a/net-mail/eps/eps-1.7-r1.ebuild b/net-mail/eps/eps-1.7-r1.ebuild
new file mode 100644 (file)
index 0000000..f010953
--- /dev/null
+++ b/net-mail/eps/eps-1.7-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="Inter7 Email Processing and mht System library"
+HOMEPAGE="http://www.inter7.com/eps"
+SRC_URI="http://www.inter7.com/eps/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+DEPEND="sys-apps/sed"
+RDEPEND=""
+
+src_prepare() {
+       sed -i -e 's:/usr:$(DESTDIR)$(prefix):g' \
+               -e 's:\(DEFS.*\):\1 $(CFLAGS):' \
+               -e 's:$(DEFS):$(DEFS) -fPIC:' \
+               -e 's:-shared:-shared -Wl,-soname,libeps.so $(LDFLAGS):' \
+               -e 's:cp -pf:cp -f:g' \
+               Makefile || die
+       default
+}
+
+src_compile() {
+       emake CC="$(tc-getCC)" AR="$(tc-getAR)"
+}
+
+src_install() {
+       emake prefix=/usr DESTDIR="${D}" LIBDIR="${D}/usr/$(get_libdir)" install
+       dodoc ChangeLog TODO doc/*
+}