net-libs/telepathy-qt: add 0.9.8, bug #699882

The new version works with Python 3 and has fixed tests.

Signed-off-by: Alexander Akulich <akulichalexander@gmail.com>
Closes: https://bugs.gentoo.org/699882
Closes: https://bugs.gentoo.org/549448
Closes: https://github.com/gentoo/gentoo/pull/13612
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/net-libs/telepathy-qt/Manifest b/net-libs/telepathy-qt/Manifest
index 2edac9f836f12c01794dde34e98fc90e610b6fe3..d915ef01694ae816eb0ad240d2de842803cc8514 100644 (file)
--- a/net-libs/telepathy-qt/Manifest
+++ b/net-libs/telepathy-qt/Manifest
@@ -1 +1,2 @@
 DIST telepathy-qt-0.9.7.tar.gz 6213405 BLAKE2B 13e2ae73bba74b4aedd55b46d0816744a4485a2a39faed610439fff40a65065a12606080012e220fc30a9d2642aba311aca6a24b540d8d22a140197911343eb8 SHA512 081daecb2509ea690079014bcc88eacbf2b3e4f4ac42aaf1b0cb264c01b801bc499a041482571d383f258cb3d3e2c6ffa5682fbe417fe807fcc25a06d2ead877
+DIST telepathy-qt-0.9.8.tar.gz 6448686 BLAKE2B 7554b812c35a09aabc0ff92fea43f633b5c2f87784c8e7b387545b31c1c92eb02f9e416930c635202fe0205c4e26c1fd63c3b4a668cf0ceeb602d8a777891cd9 SHA512 fad662c02417c8e4e239d438ea3549226e589442aea8418c8922a6b78ff88422a36c1cc0d2e3591240fac115390a7fbdb1b4deea98187051cc811175b60b9e8b

diff --git a/net-libs/telepathy-qt/telepathy-qt-0.9.8.ebuild b/net-libs/telepathy-qt/telepathy-qt-0.9.8.ebuild
new file mode 100644 (file)
index 0000000..1cbcf4a
--- /dev/null
+++ b/net-libs/telepathy-qt/telepathy-qt-0.9.8.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+inherit python-any-r1 cmake-utils virtualx
+
+DESCRIPTION="Qt bindings for the Telepathy D-Bus protocol"
+HOMEPAGE="https://telepathy.freedesktop.org/"
+SRC_URI="https://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="debug farstream test"
+
+RDEPEND="
+       dev-qt/qtcore:5
+       dev-qt/qtdbus:5
+       dev-qt/qtgui:5
+       dev-qt/qtnetwork:5
+       dev-qt/qtxml:5
+       farstream? (
+               >=net-libs/telepathy-farstream-0.2.2
+               >=net-libs/telepathy-glib-0.18.0
+       )
+"
+DEPEND="${RDEPEND}
+       test? (
+               dev-libs/dbus-glib
+               dev-libs/glib:2
+               dev-qt/qttest:5
+               $(python_gen_any_dep '
+                       dev-python/dbus-python[${PYTHON_USEDEP}]
+               ')
+       )
+"
+BDEPEND="
+       ${PYTHON_DEPS}
+       virtual/pkgconfig
+"
+RESTRICT="!test? ( test )"
+
+python_check_deps() {
+       has_version "dev-python/dbus-python[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+       use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DENABLE_DEBUG_OUTPUT=$(usex debug)
+               -DENABLE_FARSTREAM=$(usex farstream)
+               -DENABLE_TESTS=$(usex test)
+               -DENABLE_EXAMPLES=OFF
+       )
+       cmake-utils_src_configure
+}
+
+src_test() {
+       pushd "${BUILD_DIR}" > /dev/null || die
+       virtx cmake-utils_src_test
+       popd > /dev/null || die
+}