dev-python/jaraco-functools: needed as a new dep to dev-python/irc

Package-Manager: portage-2.2.26

diff --git a/dev-python/jaraco-functools/Manifest b/dev-python/jaraco-functools/Manifest
new file mode 100644 (file)
index 0000000..2bef306
--- /dev/null
+++ b/dev-python/jaraco-functools/Manifest
@@ -0,0 +1 @@
+DIST jaraco.functools-1.8.1.tar.gz 6125 SHA256 766cd9caed0c18dfbf744dcd05d1f171f03e64ab8f7363d5b2521ba200383c5a SHA512 d67795340238bd646bea450e8bb37fb64bca66a41a4b8f385f4a986b880578edfa2dad23b820a1a9cce7460dc530a2de2a219362e9cd0ced851040e86fb70f21 WHIRLPOOL bd050b7daa52f2f5043ca2209562472b96d9ec5d417edf96bf686eb0f60a4bde6b69890557140f7f0b278e8d612c702b01a5b72ccae5b894b3646d37582a1da5

diff --git a/dev-python/jaraco-functools/jaraco-functools-1.8.1.ebuild b/dev-python/jaraco-functools/jaraco-functools-1.8.1.ebuild
new file mode 100644 (file)
index 0000000..9914b72
--- /dev/null
+++ b/dev-python/jaraco-functools/jaraco-functools-1.8.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Additional functions used by other projects by developer jaraco"
+HOMEPAGE="https://github.com/jaraco/jaraco.functools"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+# https://github.com/jaraco/jaraco.functools/issues/3
+RESTRICT="test"
+
+RDEPEND="dev-python/six[${PYTHON_USEDEP}]
+       $(python_gen_cond_dep 'dev-python/backports-functools-lru-cache[${PYTHON_USEDEP}]' python2_7)
+"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+       >=dev-python/setuptools_scm-1.9[${PYTHON_USEDEP}]
+       test? (
+               ${RDEPEND}
+               >=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+               dev-python/pytest-runner[${PYTHON_USEDEP}]
+       )
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_prepare_all() {
+       if use test && has_version "${CATEGORY}/${PN}"; then
+               die "Ensure $PN is not already installed or the test suite will fail"
+       fi
+       distutils-r1_python_prepare_all
+}
+
+python_test() {
+       PYTHONPATH=. py.test || die "tests failed with ${EPYTHON}"
+}

diff --git a/dev-python/jaraco-functools/metadata.xml b/dev-python/jaraco-functools/metadata.xml
new file mode 100644 (file)
index 0000000..811c8d1
--- /dev/null
+++ b/dev-python/jaraco-functools/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+       <herd>proxy-maintainers</herd>
+       <maintainer>
+               <email>sautier.louis@gmail.com</email>
+               <name>Louis Sautier</name>
+               <description>Proxied maintainer; set to assignee in all bugs</description>
+       </maintainer>
+       <upstream>
+               <remote-id type="pypi">jaraco.functools</remote-id>
+               <remote-id type="github">jaraco/jaraco.functools</remote-id>
+       </upstream>
+</pkgmetadata>