kde-base/kcheckpass: Add alternative deps on pam providers, fix DEPEND

kde-plasma/plasma-workspace and kde-plasma/kscreenlocker will start to
block kde-base/kdebase-pam due to colliding files in /etc/pam.d/
In order to avoid another full block, let kcheckpass be satisfied by these
packages as well.

Package-Manager: portage-2.2.20.1

diff --git a/kde-base/kcheckpass/kcheckpass-4.11.22-r1.ebuild b/kde-base/kcheckpass/kcheckpass-4.11.22-r1.ebuild
new file mode 100644 (file)
index 0000000..bc4f592
--- /dev/null
+++ b/kde-base/kcheckpass/kcheckpass-4.11.22-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="A simple password checker, used by any software in need of user authentication"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug pam"
+
+DEPEND="
+       pam? ( virtual/pam )
+"
+RDEPEND="${DEPEND}
+       pam? ( || (
+               >=kde-base/kdebase-pam-7
+               kde-plasma/kscreenlocker
+               <kde-plasma/plasma-workspace-5.4.50
+       ) )
+"
+
+src_prepare() {
+       kde4-meta_src_prepare
+
+       use pam && epatch "${FILESDIR}/${PN}-4.4.2-no-SUID-no-GUID.patch"
+}
+
+src_configure() {
+       local mycmakeargs=(
+               $(cmake-utils_use_with pam)
+       )
+
+       kde4-meta_src_configure
+}