games-emulation/pcsxr: Bump to 1.9.94_p20190306 snapshot

Closes: https://bugs.gentoo.org/647336
Signed-off-by: Michał Górny <mgorny@gentoo.org>

diff --git a/games-emulation/pcsxr/Manifest b/games-emulation/pcsxr/Manifest
index 84560f3e522abcd6c57c0b2b4b5f99af7a2d09d6..1d6c9ecd7d613aad2f4b96c0cfd55aabd4e74a8e 100644 (file)
--- a/games-emulation/pcsxr/Manifest
+++ b/games-emulation/pcsxr/Manifest
@@ -1 +1,2 @@
 DIST pcsxr-1.9.94.zip 2631125 BLAKE2B 686503faffccc820bcac73bc69056ffe05176779ee49b834ce0da84c40a047b7882ca7b91a7b7f95ab153329ca6368ae545bbe567cac6a9bdba1a434c397862c SHA512 c49471c27692fbf22da32d2f5697a1dfed3dbdbfdb86cb789b0ea6cddb2a7da4f3390e4568f4e9385bf30d6baff0f2a591a80f424cf0c640cae0035ba81dce39
+DIST pcsxr-62467b86871aee3d70c7445f3cb79f0858ec566e.tar.gz 2229537 BLAKE2B 2f5c11c16d79b6747ccc5f7c655e99663a882e264548c136ff6d4b1321788a10b1475c023e0c7e0892aeb94032c522f2a0e6312e6cf66f608e1a1d7897aea809 SHA512 894e795c3616bb6abf87d144e1a2409142d457f2f2c04c4287e2804bb06caf008f42501089d555b5e43e6b2d6d2e8ac9a7d78842bed975b1b4b94465f4ed3a3c

diff --git a/games-emulation/pcsxr/pcsxr-1.9.94_p20190306.ebuild b/games-emulation/pcsxr/pcsxr-1.9.94_p20190306.ebuild
new file mode 100644 (file)
index 0000000..d51b029
--- /dev/null
+++ b/games-emulation/pcsxr/pcsxr-1.9.94_p20190306.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit cmake-utils xdg-utils
+
+EGIT_COMMIT="62467b86871aee3d70c7445f3cb79f0858ec566e"
+MY_P=${PN}-${EGIT_COMMIT}
+DESCRIPTION="PCSX-Reloaded: a fork of PCSX, the discontinued Playstation emulator"
+HOMEPAGE="https://github.com/iCatButler/pcsxr"
+SRC_URI="https://github.com/iCatButler/pcsxr/archive/${EGIT_COMMIT}.tar.gz -> ${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2 public-domain"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="alsa archive ccdda cdio libav openal oss pulseaudio +sdl"
+REQUIRED_USE="?? ( alsa openal oss pulseaudio sdl )"
+
+RDEPEND="
+       dev-libs/glib:2
+       media-libs/libsdl2[joystick]
+       sys-libs/zlib:=
+       x11-libs/gtk+:3
+       x11-libs/libX11
+       x11-libs/libXext
+       x11-libs/libXtst
+       x11-libs/libXv
+       x11-libs/libXxf86vm
+       virtual/libintl
+       virtual/opengl
+       archive? ( app-arch/libarchive:= )
+       alsa? ( media-libs/alsa-lib:= )
+       cdio? ( dev-libs/libcdio:= )
+       ccdda? (
+               !libav? ( >=media-video/ffmpeg-3:= )
+               libav? ( media-video/libav:= )
+       )
+       openal? ( media-libs/openal:= )
+       pulseaudio? ( media-sound/pulseaudio:= )
+       sdl? ( media-libs/libsdl2:=[sound] )
+"
+DEPEND="${RDEPEND}
+       x11-base/xorg-proto"
+BDEPEND="
+       app-arch/unzip
+       dev-util/intltool
+       sys-devel/gettext:0
+"
+
+src_configure() {
+       local sound_backend
+
+       if use pulseaudio; then
+               sound_backend=pulse
+       elif use sdl; then
+               sound_backend=sdl
+       elif use openal; then
+               sound_backend=openal
+       elif use alsa; then
+               sound_backend=alsa
+       elif use oss; then
+               sound_backend=oss
+       else
+               sound_backend=null
+       fi
+
+       local mycmakeargs=(
+               -DENABLE_CCDDA=$(usex ccdda)
+               -DUSE_LIBARCHIVE=$(usex archive)
+               -DUSE_LIBCDIO=$(usex cdio)
+               -DSND_BACKEND=${sound_backend}
+       )
+
+       cmake-utils_src_configure
+}
+
+src_install() {
+       cmake-utils_src_install
+       mv "${ED}"/usr/share/doc/pcsxr/* "${ED}/usr/share/doc/${PF}/" || die
+       rmdir "${ED}"/usr/share/doc/pcsxr || die
+}
+
+pkg_postinst() {
+       xdg_icon_cache_update
+}
+
+pkg_postrm() {
+       xdg_icon_cache_update
+}