dev-python/jaraco-itertools: bump to 2.3, fix deps, add Py3.6

Package-Manager: Portage-2.3.40, Repoman-2.3.9

diff --git a/dev-python/jaraco-itertools/Manifest b/dev-python/jaraco-itertools/Manifest
index 8364b08b00eb31328ebc48d76038efd867e8cac0..c242332bdbbc8d6a0ee1966537b93f9d42649fdd 100644 (file)
--- a/dev-python/jaraco-itertools/Manifest
+++ b/dev-python/jaraco-itertools/Manifest
@@ -1,2 +1,3 @@
 DIST jaraco.itertools-1.7.1.tar.gz 10224 BLAKE2B 11f22156736f283604d75aaf48975a483be972ac3b1feabead224c4a323575c3978429638ada7c82037f9cbf9ce3a966a535acbdffdfdf880ebb8db152506cf4 SHA512 e149de3368137db4379d02858be0cbb3b6dc1e81cc06eb0f53064a55c8e25fb09b2b4387035dda29928bdf54e22d28c9d9744dfbd82a6cf4e4c90b5d42b31dfb
 DIST jaraco.itertools-2.0.tar.gz 11158 BLAKE2B 4fe42711819e5aca6a8995037ba05f4858e14cb55ed0fc2d54d805e00b5c12229cb2148d515179e4b7c14cdfe64e4162b1891481b0906fb96d832c155af758a3 SHA512 56877e141da1c79499dee2e3cfd15a81f07d6cf6fa1ee88f4ae387423d91106f41c1787fecc194755fddc521d6284763cba93083904e67d548c053d1584a4438
+DIST jaraco.itertools-2.3.tar.gz 12857 BLAKE2B 714b123965af3ff593205aab373f3097709729377cd867ca2a7ccbb7795b1818f47b0b316d4c927c9aec4eb66fe1da63b44c1d60db310dd97b5444b01f7db04d SHA512 070a442531fd079fefcb61bbbdb0cc98bc88cbc5f23f6cb40ee1fafbc9a259c69e0a373e949ab54d22836f54b0de41e1b09d10692f92d18030825ca09345be48

diff --git a/dev-python/jaraco-itertools/jaraco-itertools-2.3.ebuild b/dev-python/jaraco-itertools/jaraco-itertools-2.3.ebuild
new file mode 100644 (file)
index 0000000..ab4fb4f
--- /dev/null
+++ b/dev-python/jaraco-itertools/jaraco-itertools-2.3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# Tests fail with PyPy and PyPy 3
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Tools for working with iterables. Complements itertools and more_itertools"
+HOMEPAGE="https://github.com/jaraco/jaraco.itertools"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+       dev-python/namespace-jaraco[${PYTHON_USEDEP}]
+       dev-python/six[${PYTHON_USEDEP}]
+       dev-python/inflect[${PYTHON_USEDEP}]
+       >=dev-python/more-itertools-4.0.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       >=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+       doc? (
+               dev-python/sphinx[${PYTHON_USEDEP}]
+               dev-python/rst-linker[${PYTHON_USEDEP}]
+       )
+       test? (
+               ${RDEPEND}
+               >=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+       )
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+       if use doc; then
+               sphinx-build docs docs/_build/html || die
+               HTML_DOCS=( docs/_build/html/. )
+       fi
+}
+
+python_test() {
+       # Override pytest options to skip flake8
+       PYTHONPATH=. py.test --override-ini="addopts=--doctest-modules" \
+               || die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+       distutils-r1_python_install_all
+       find "${ED}" -name '*.pth' -delete || die
+}