dev-libs/libevent: Add live ebuild to track patches-2.1

Package-Manager: Portage-2.3.63, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

diff --git a/dev-libs/libevent/libevent-2.1.9999.ebuild b/dev-libs/libevent/libevent-2.1.9999.ebuild
new file mode 100644 (file)
index 0000000..edf6dbc
--- /dev/null
+++ b/dev-libs/libevent/libevent-2.1.9999.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools git-r3 multilib-minimal
+
+DESCRIPTION="Library to execute a function when a specific event occurs on a file descriptor"
+EGIT_BRANCH="patches-$(ver_cut 1-2)"
+EGIT_REPO_URI="https://github.com/libevent/libevent"
+HOMEPAGE="
+       http://libevent.org/
+       ${EGIT_REPO_URI}
+"
+
+LICENSE="BSD"
+# libevent-2.1.so.6
+SLOT="0/2.1-6"
+KEYWORDS=""
+IUSE="debug libressl +ssl static-libs test +threads"
+RESTRICT="test"
+
+DEPEND="
+       ssl? (
+               !libressl? ( >=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}] )
+               libressl? ( dev-libs/libressl:0=[${MULTILIB_USEDEP}] )
+       )
+"
+RDEPEND="
+       ${DEPEND}
+       !<=dev-libs/9libs-1.0
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+       /usr/include/event2/event-config.h
+)
+DOCS=(
+       ChangeLog{,-1.4,-2.0}
+)
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+multilib_src_configure() {
+       # fix out-of-source builds
+       mkdir -p test || die
+
+       ECONF_SOURCE="${S}" \
+       econf \
+               --disable-samples \
+               $(use_enable debug debug-mode) \
+               $(use_enable debug malloc-replacement) \
+               $(use_enable ssl openssl) \
+               $(use_enable static-libs static) \
+               $(use_enable test libevent-regress) \
+               $(use_enable threads thread-support)
+}
+
+multilib_src_install_all() {
+       einstalldocs
+       find "${ED}" -name '*.la' -delete || die
+}