sys-cluster/kubectl: Add bash and zsh completion

Package-Manager: Portage-2.3.6, Repoman-2.3.3

diff --git a/sys-cluster/kubectl/kubectl-1.7.3-r1.ebuild b/sys-cluster/kubectl/kubectl-1.7.3-r1.ebuild
new file mode 100644 (file)
index 0000000..89ea955
--- /dev/null
+++ b/sys-cluster/kubectl/kubectl-1.7.3-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit golang-build golang-vcs-snapshot bash-completion-r1
+
+EGO_PN="k8s.io/kubernetes"
+ARCHIVE_URI="https://github.com/kubernetes/kubernetes/archive/v${PV}.tar.gz -> kubernetes-${PV}.tar.gz"
+KEYWORDS="~amd64"
+
+DESCRIPTION="CLI to run commands against Kubernetes clusters"
+HOMEPAGE="https://github.com/kubernetes/kubernetes https://kubernetes.io"
+SRC_URI="${ARCHIVE_URI}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+DEPEND="dev-go/go-bindata"
+
+RESTRICT="test"
+
+src_prepare() {
+       default
+       sed -i -e "/vendor\/github.com\/jteeuwen\/go-bindata\/go-bindata/d" src/${EGO_PN}/hack/lib/golang.sh || die
+       sed -i -e "/export PATH/d" src/${EGO_PN}/hack/generate-bindata.sh || die
+}
+
+src_compile() {
+       LDFLAGS="" GOPATH="${WORKDIR}/${P}" emake -j1 -C src/${EGO_PN} WHAT=cmd/${PN}
+       pushd src/${EGO_PN} || die
+       _output/bin/${PN} completion bash > ${PN}.bash
+       _output/bin/${PN} completion zsh > ${PN}.zsh
+       popd || die
+}
+
+src_install() {
+       pushd src/${EGO_PN} || die
+       dobin _output/bin/${PN}
+
+       newbashcomp ${PN}.bash ${PN}
+       insinto /usr/share/zsh/site-functions
+       newins ${PN}.zsh ${PN}
+
+       popd || die
+}