dev-perl/Emacs-PDE: EAPI6 + Tests

- EAPI6ify
- Add basic tests ( Upstream has none to speak of )

Package-Manager: Portage-2.3.8, Repoman-2.3.3

diff --git a/dev-perl/Emacs-PDE/Emacs-PDE-0.2.16-r2.ebuild b/dev-perl/Emacs-PDE/Emacs-PDE-0.2.16-r2.ebuild
new file mode 100644 (file)
index 0000000..e142d1e
--- /dev/null
+++ b/dev-perl/Emacs-PDE/Emacs-PDE-0.2.16-r2.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DIST_AUTHOR=YEWENBIN
+
+inherit perl-module elisp-common
+
+DESCRIPTION="Perl Develop Environment in Emacs"
+
+LICENSE="|| ( Artistic GPL-1 GPL-2 GPL-3 )"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND="virtual/emacs"
+DEPEND="dev-perl/Module-Build
+               ${RDEPEND}"
+myconf="--elispdir=${D}${SITELISP}/pde"
+
+src_test() {
+       local MODULES=(
+               "Emacs::PDE ${PV}"
+               "Emacs::PDE::Util"
+       )
+       local failed=()
+       for dep in "${MODULES[@]}"; do
+               ebegin "Compile testing ${dep}"
+                       perl -Mblib="${S}" -M"${dep} ()" -e1
+               eend $? || failed+=( "$dep" )
+       done
+       if [[ ${failed[@]} ]]; then
+               echo
+               eerror "One or more modules failed compile:";
+               for dep in "${failed[@]}"; do
+                       eerror "  ${dep}"
+               done
+               die "Failing due to module compilation errors";
+       fi
+       perl-module_src_test
+}