sys-cluster/torque: dependency cleanup

Dependency atoms listed in the ebuild were rather significantly mis-matching what
is actually linked to.  Cleaned them up, added slot and slot-operators as needed.

Added libressl to IUSE but didn't test if libressl is a drop-in replacement for
openssl -- the situation should be better either way since it was a magic dep
until now.

Also bumped EAPI for torque-2.x so it is no longer deprecated, and adjusted how
the cpusets flag is added to configure.

Package-Manager: portage-2.2.28

diff --git a/sys-cluster/torque/torque-2.5.13.ebuild b/sys-cluster/torque/torque-2.5.13-r1.ebuild
similarity index 94%
rename from sys-cluster/torque/torque-2.5.13.ebuild
rename to sys-cluster/torque/torque-2.5.13-r1.ebuild
index 252ac35161fc724bf837c77b2c1e8fc8c393957c..82934c0558f9511d245a5a99273c4bb97f2c55d8 100644 (file)
--- a/sys-cluster/torque/torque-2.5.13.ebuild
+++ b/sys-cluster/torque/torque-2.5.13-r1.ebuild
@@ -1,8 +1,8 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
-EAPI=4
+EAPI=5
 
 inherit autotools-utils eutils flag-o-matic linux-info
 
@@ -17,16 +17,21 @@ KEYWORDS="alpha amd64 hppa ia64 ~mips ppc ppc64 sparc x86"
 IUSE="cpusets +crypt doc drmaa kernel_linux munge server static-libs +syslog threads tk xml"
 
 # ed is used by makedepend-sh
-DEPEND_COMMON="sys-libs/ncurses
-       sys-libs/readline
+DEPEND_COMMON="
+       sys-libs/readline:0=
        munge? ( sys-auth/munge )
-       tk? ( dev-lang/tk )
+       tk? (
+               dev-lang/tk:0=
+               dev-lang/tcl:0=
+       )
        syslog? ( virtual/logger )
-       !games-util/qstat"
+       !!games-util/qstat"
 
+# libncurses.so is just needed so that configure will pass for the readline check
 DEPEND="${DEPEND_COMMON}
+       sys-libs/ncurses:*
        sys-apps/ed
-       !sys-cluster/slurm"
+       !!sys-cluster/slurm"
 
 RDEPEND="${DEPEND_COMMON}
        crypt? ( net-misc/openssh )
@@ -49,12 +54,11 @@ pkg_setup() {
                fi
        fi
 
-       USE_CPUSETS="--disable-cpuset"
        if use cpusets; then
                if ! use kernel_linux; then
                        einfo
                        elog "    Torque currently only has support for cpusets in linux."
-                       elog "Assuming you didn't really want this USE flag."
+                       elog "Assuming you didn't really want this USE flag and ignoring."
                        einfo
                else
                        linux-info_pkg_setup
@@ -68,7 +72,6 @@ pkg_setup() {
                                elog "your kernel with CONFIG_CPUSETS enabled."
                                einfo
                        fi
-                       USE_CPUSETS="--enable-cpuset"
                fi
        fi
 }
@@ -92,7 +95,6 @@ src_configure() {
        local myeconfargs=( --with-rcp=mom_rcp )
 
        use crypt && myeconfargs=( --with-rcp=scp )
-
        myeconfargs+=(
                $(use_enable tk gui)
                $(use_enable tk tcl-qstat)
@@ -102,12 +104,12 @@ src_configure() {
                $(use_enable threads high-availability)
                $(use_enable xml server-xml)
                $(use_enable munge munge-library)
+               $(usex kernel_linux $(use_enable cpusets cpuset) --disable-cpuset)
                --with-server-home=${PBS_SERVER_HOME}
                --with-environ=/etc/pbs_environment
                --with-default-server=${PBS_SERVER_NAME}
                --disable-gcc-warnings
                --with-tcp-retry-limit=2
-               ${USE_CPUSETS}
                )
        autotools-utils_src_configure
 }

diff --git a/sys-cluster/torque/torque-4.1.7.ebuild b/sys-cluster/torque/torque-4.1.7-r1.ebuild
similarity index 92%
rename from sys-cluster/torque/torque-4.1.7.ebuild
rename to sys-cluster/torque/torque-4.1.7-r1.ebuild
index ea148c3c701deb70680f30297bbc76635ee7f6ad..86dfeb5b6d3bc57e1ed5d41a53d134e5cb43fd96 100644 (file)
--- a/sys-cluster/torque/torque-4.1.7.ebuild
+++ b/sys-cluster/torque/torque-4.1.7-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -15,20 +15,27 @@ SRC_URI="http://www.adaptivecomputing.com/index.php?wpfb_dl=1690 -> ${P}.tar.gz"
 LICENSE="torque-2.5"
 SLOT="0"
 KEYWORDS="alpha amd64 hppa ia64 ~mips ppc ppc64 sparc x86"
-IUSE="cpusets +crypt doc drmaa kernel_linux munge nvidia server +syslog tk"
+IUSE="cpusets +crypt doc drmaa kernel_linux libressl munge nvidia server +syslog tk"
 
 DEPEND_COMMON="
-       sys-libs/ncurses
-       sys-libs/readline
+       sys-libs/zlib
+       sys-libs/readline:0=
+       libressl? ( dev-libs/libressl:0= )
+       !libressl? ( dev-libs/openssl:0= )
        cpusets? ( sys-apps/hwloc )
        munge? ( sys-auth/munge )
        nvidia? ( >=x11-drivers/nvidia-drivers-275 )
-       tk? ( dev-lang/tk )
+       tk? (
+               dev-lang/tk:0=
+               dev-lang/tcl:0=
+       )
        syslog? ( virtual/logger )
-       !games-util/qstat"
+       !!games-util/qstat"
 
+# libncurses.so is only needed for the configure check on readline to pass
 DEPEND="${DEPEND_COMMON}
-       !sys-cluster/slurm"
+       sys-libs/ncurses:*
+       !!sys-cluster/slurm"
 
 RDEPEND="${DEPEND_COMMON}
        crypt? ( net-misc/openssh )
@@ -53,12 +60,11 @@ pkg_setup() {
                fi
        fi
 
-       USE_CPUSETS="--disable-cpuset"
        if use cpusets; then
                if ! use kernel_linux; then
                        einfo
                        elog "    Torque currently only has support for cpusets in linux."
-                       elog "Assuming you didn't really want this USE flag."
+                       elog "Assuming you didn't really want this USE flag, and ignoring its state."
                        einfo
                else
                        linux-info_pkg_setup
@@ -68,7 +74,6 @@ pkg_setup() {
                                elog "your kernel with CONFIG_CPUSETS enabled."
                                einfo
                        fi
-                       USE_CPUSETS="--enable-cpuset"
                fi
        fi
 }
@@ -100,13 +105,13 @@ src_configure() {
                $(use_enable drmaa) \
                $(use_enable munge munge-auth) \
                $(use_enable nvidia nvidia-gpus) \
+               $(usex kernel_linux $(use_enable cpusets cpuset) --disable-cpuset) \
                --with-server-home=${PBS_SERVER_HOME} \
                --with-environ=/etc/pbs_environment \
                --with-default-server=${PBS_SERVER_NAME} \
                --disable-gcc-warnings \
                --with-tcp-retry-limit=2 \
                --without-loadlibfile \
-               ${USE_CPUSETS} \
                ${myconf}
 }
 

diff --git a/sys-cluster/torque/torque-4.2.9-r4.ebuild b/sys-cluster/torque/torque-4.2.9-r5.ebuild
similarity index 89%
rename from sys-cluster/torque/torque-4.2.9-r4.ebuild
rename to sys-cluster/torque/torque-4.2.9-r5.ebuild
index 372a4a12c68d0c7b43b3db125aa8985937659a20..601227fd7edc6f254afb9f59d1390e41134c5fa4 100644 (file)
--- a/sys-cluster/torque/torque-4.2.9-r4.ebuild
+++ b/sys-cluster/torque/torque-4.2.9-r5.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -15,20 +15,28 @@ SRC_URI="http://www.adaptivecomputing.com/index.php?wpfb_dl=2849 -> ${P}.tar.gz"
 LICENSE="torque-2.5"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
-IUSE="cpusets +crypt doc drmaa kernel_linux munge nvidia server +syslog tk"
+IUSE="cpusets +crypt doc drmaa kernel_linux libressl munge nvidia server +syslog tk"
 
 DEPEND_COMMON="
-       sys-libs/ncurses
-       sys-libs/readline:*
+       sys-libs/zlib
+       sys-libs/readline:0=
+       dev-libs/libxml2
+       !libressl? ( dev-libs/openssl:0= )
+       libressl? ( dev-libs/libressl:0= )
        cpusets? ( sys-apps/hwloc )
        munge? ( sys-auth/munge )
        nvidia? ( >=x11-drivers/nvidia-drivers-275 )
-       tk? ( dev-lang/tk:0 )
+       tk? (
+               dev-lang/tk:0=
+               dev-lang/tcl:0=
+       )
        syslog? ( virtual/logger )
-       !games-util/qstat"
+       !!games-util/qstat"
 
+# libncurses.so is only needed for configure check on readline
 DEPEND="${DEPEND_COMMON}
-       !sys-cluster/slurm"
+       sys-libs/ncurses:*
+       !!sys-cluster/slurm"
 
 RDEPEND="${DEPEND_COMMON}
        crypt? ( net-misc/openssh )
@@ -53,12 +61,11 @@ pkg_setup() {
                fi
        fi
 
-       USE_CPUSETS="--disable-cpuset"
        if use cpusets; then
                if ! use kernel_linux; then
                        einfo
                        elog "    Torque currently only has support for cpusets in linux."
-                       elog "Assuming you didn't really want this USE flag."
+                       elog "Assuming you didn't really want this USE flag and ignoring its state."
                        einfo
                else
                        linux-info_pkg_setup
@@ -68,7 +75,6 @@ pkg_setup() {
                                elog "your kernel with CONFIG_CPUSETS enabled."
                                einfo
                        fi
-                       USE_CPUSETS="--enable-cpuset"
                fi
        fi
 }
@@ -100,13 +106,13 @@ src_configure() {
                $(use_enable drmaa) \
                $(use_enable munge munge-auth) \
                $(use_enable nvidia nvidia-gpus) \
+               $(usex kernel_linux $(use_enable cpusets cpuset) --disable-cpuset) \
                --with-server-home=${PBS_SERVER_HOME} \
                --with-environ=/etc/pbs_environment \
                --with-default-server=${PBS_SERVER_NAME} \
                --disable-gcc-warnings \
                --with-tcp-retry-limit=2 \
                --without-loadlibfile \
-               ${USE_CPUSETS} \
                ${myconf}
 }