sys-apps/bleachbit: Bump to 2.1 beta, EAPI=7

Signed-off-by: Christian Tietz <christian.tietz@mailbox.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11
Closes: https://github.com/gentoo/gentoo/pull/11174
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/sys-apps/bleachbit/Manifest b/sys-apps/bleachbit/Manifest
index 43f85d60fbf1f4dda366d77eed53a682f0436542..49b85b773fb2bf74cc1848c9079526c38cc35f70 100644 (file)
--- a/sys-apps/bleachbit/Manifest
+++ b/sys-apps/bleachbit/Manifest
@@ -1 +1,2 @@
 DIST bleachbit-2.0.tar.gz 886357 BLAKE2B f63ded34d245df892b2c14683ceaae8b57e786a8ab3111e7f76d484c6d3db404996119ab4114c3ae025848936a784878b3f100cf2ca8737401a6daaaf74a077e SHA512 adf5c2f2382b2eaab0eb2b4a173b392c160af7974f223c74ae51a30423514a15b98f04194b9ccde209b5c067d8481f0f1ee28651896d3002fcfa3927d8db056b
+DIST bleachbit-2.1.tar.gz 1080424 BLAKE2B 684fc7db66b0de1aa0a4673f6b9b7887a3dcd14946e599771e548706d6ecfb54e264e6e953b986bd160e182d28ee4468dac0e637fc010fc4f0d31d5b7448c3ad SHA512 eac62c02bc196760869b6c2d31f13d52220a2e62a7e9a7584ebcbe498e14d5c606937cfef9a1cfd2f585b1b9641572c2a81e28515679f8f6a72e95e97b6a0cd8

diff --git a/sys-apps/bleachbit/bleachbit-2.1.ebuild b/sys-apps/bleachbit/bleachbit-2.1.ebuild
new file mode 100644 (file)
index 0000000..6933900
--- /dev/null
+++ b/sys-apps/bleachbit/bleachbit-2.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite(+)"
+
+inherit desktop distutils-r1
+
+DESCRIPTION="Clean junk to free disk space and to maintain privacy"
+HOMEPAGE="https://www.bleachbit.org"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+gtk"
+
+RDEPEND="gtk? ( dev-python/pygtk:2[$PYTHON_USEDEP] )"
+DEPEND="${RDEPEND}"
+BDEPEND="sys-devel/gettext"
+
+python_prepare_all() {
+       # choose correct Python implementation, bug #465254
+       sed -i 's/python/$(PYTHON)/g' po/Makefile || die
+
+       distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+       emake -C po local
+}
+
+python_install() {
+       distutils-r1_python_install
+       python_newscript ${PN}.py ${PN}
+}
+
+python_install_all() {
+       distutils-r1_python_install_all
+       emake -C po DESTDIR="${D}" install
+
+       # https://bugs.gentoo.org/388999
+       insinto /usr/share/bleachbit/cleaners
+       doins cleaners/*.xml
+
+       doicon ${PN}.png
+       domenu ${PN}.desktop
+}
+
+pkg_postinst() {
+       elog "Bleachbit has optional notification support. To enable, please install:"
+       elog ""
+       elog "  dev-python/notify-python"
+}