sys-boot/plymouth: fixing musl and updating 9999 ebuild

Closes: https://bugs.gentoo.org/651874
Package-Manager: Portage-2.3.27, Repoman-2.3.9

diff --git a/sys-boot/plymouth/plymouth-0.9.3-r2.ebuild b/sys-boot/plymouth/plymouth-0.9.3-r2.ebuild
new file mode 100644 (file)
index 0000000..5ffedf3
--- /dev/null
+++ b/sys-boot/plymouth/plymouth-0.9.3-r2.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic
+SRC_URI="https://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/gentoo-logo.png"
+
+if [[ ${PV} == 9999 ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://anongit.freedesktop.org/git/plymouth"
+else
+       SRC_URI="${SRC_URI} https://www.freedesktop.org/software/plymouth/releases/${P}.tar.xz"
+       KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+inherit autotools readme.gentoo-r1 systemd toolchain-funcs
+
+DESCRIPTION="Graphical boot animation (splash) and logger"
+HOMEPAGE="https://cgit.freedesktop.org/plymouth/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="debug gdm +gtk +libkms +pango static-libs"
+
+CDEPEND="
+       >=media-libs/libpng-1.2.16:=
+       gtk? (
+               dev-libs/glib:2
+               >=x11-libs/gtk+-3.14:3
+               x11-libs/cairo
+       )
+       libkms? ( x11-libs/libdrm[libkms] )
+       pango? ( >=x11-libs/pango-1.21 )
+"
+DEPEND="${CDEPEND}
+       elibc_musl? ( sys-libs/rpmatch-standalone )
+       app-text/docbook-xsl-stylesheets
+       dev-libs/libxslt
+       virtual/pkgconfig
+"
+# Block due bug #383067
+RDEPEND="${CDEPEND}
+       virtual/udev
+       !<sys-kernel/dracut-0.37-r3
+"
+
+DOC_CONTENTS="
+       Follow the following instructions to set up Plymouth:\n
+       https://wiki.gentoo.org/wiki/Plymouth#Configuration
+"
+
+PATCHES=(
+       "${FILESDIR}"/0.9.3-glibc-sysmacros.patch
+)
+
+src_prepare() {
+       use elibc_musl && append-ldflags -lrpmatch
+       default
+       eautoreconf
+}
+
+src_configure() {
+       local myconf=(
+               --with-system-root-install=no
+               --localstatedir=/var
+               --without-rhgb-compat-link
+               --enable-documentation
+               --enable-systemd-integration
+               --with-systemdunitdir="$(systemd_get_systemunitdir)"
+               $(use_enable !static-libs shared)
+               $(use_enable static-libs static)
+               $(use_enable debug tracing)
+               $(use_enable gtk gtk)
+               $(use_enable libkms drm)
+               $(use_enable pango)
+               $(use_enable gdm gdm-transition)
+       )
+       econf "${myconf[@]}"
+}
+
+src_install() {
+       default
+
+       insinto /usr/share/plymouth
+       newins "${DISTDIR}"/gentoo-logo.png bizcom.png
+
+       # Install compatibility symlinks as some rdeps hardcode the paths
+       dosym /usr/bin/plymouth /bin/plymouth
+       dosym /usr/sbin/plymouth-set-default-theme /sbin/plymouth-set-default-theme
+       dosym /usr/sbin/plymouthd /sbin/plymouthd
+
+       readme.gentoo_create_doc
+
+       # looks like make install create /var/run/plymouth
+       # this is not needed for systemd, same should hold for openrc
+       # so remove
+       rm -rf "${D}"/var/run
+}
+
+pkg_postinst() {
+       readme.gentoo_print_elog
+       if ! has_version "sys-kernel/dracut" && ! has_version "sys-kernel/genkernel-next[plymouth]"; then
+               ewarn "If you want initramfs builder with plymouth support, please emerge"
+               ewarn "sys-kernel/dracut or sys-kernel/genkernel-next[plymouth]."
+       fi
+}

diff --git a/sys-boot/plymouth/plymouth-9999.ebuild b/sys-boot/plymouth/plymouth-9999.ebuild
index 375f98aabb346f6224d6bda974eca23c8e13c952..5ffedf306a90ae620da250f2df7bb11050e253ef 100644 (file)
--- a/sys-boot/plymouth/plymouth-9999.ebuild
+++ b/sys-boot/plymouth/plymouth-9999.ebuild
@@ -3,13 +3,15 @@
 
 EAPI=6
 
+inherit flag-o-matic
 SRC_URI="https://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/gentoo-logo.png"
 
 if [[ ${PV} == 9999 ]]; then
-       EGIT_REPO_URI="https://anongit.freedesktop.org/git/plymouth"
        inherit git-r3
+       EGIT_REPO_URI="https://anongit.freedesktop.org/git/plymouth"
 else
        SRC_URI="${SRC_URI} https://www.freedesktop.org/software/plymouth/releases/${P}.tar.xz"
+       KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
 fi
 
 inherit autotools readme.gentoo-r1 systemd toolchain-funcs
@@ -19,8 +21,6 @@ HOMEPAGE="https://cgit.freedesktop.org/plymouth/"
 
 LICENSE="GPL-2"
 SLOT="0"
-[[ ${PV} == 9999 ]] || \
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
 IUSE="debug gdm +gtk +libkms +pango static-libs"
 
 CDEPEND="
@@ -28,11 +28,15 @@ CDEPEND="
        gtk? (
                dev-libs/glib:2
                >=x11-libs/gtk+-3.14:3
-               x11-libs/cairo )
+               x11-libs/cairo
+       )
        libkms? ( x11-libs/libdrm[libkms] )
        pango? ( >=x11-libs/pango-1.21 )
 "
 DEPEND="${CDEPEND}
+       elibc_musl? ( sys-libs/rpmatch-standalone )
+       app-text/docbook-xsl-stylesheets
+       dev-libs/libxslt
        virtual/pkgconfig
 "
 # Block due bug #383067
@@ -51,6 +55,7 @@ PATCHES=(
 )
 
 src_prepare() {
+       use elibc_musl && append-ldflags -lrpmatch
        default
        eautoreconf
 }
@@ -60,6 +65,7 @@ src_configure() {
                --with-system-root-install=no
                --localstatedir=/var
                --without-rhgb-compat-link
+               --enable-documentation
                --enable-systemd-integration
                --with-systemdunitdir="$(systemd_get_systemunitdir)"
                $(use_enable !static-libs shared)