games-puzzle/arrows: Stop using games.eclass

Package-Manager: Portage-2.3.28, Repoman-2.3.9

diff --git a/games-puzzle/arrows/arrows-0.6-r1.ebuild b/games-puzzle/arrows/arrows-0.6-r1.ebuild
new file mode 100644 (file)
index 0000000..5e3b5c6
--- /dev/null
+++ b/games-puzzle/arrows/arrows-0.6-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="Simple maze-like game where you navigate around and destroy arrows"
+HOMEPAGE="http://noreason.ca/?file=software"
+SRC_URI="http://noreason.ca/data/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND=">=x11-libs/gtk+-2.4:2"
+DEPEND="${RDEPEND}
+       virtual/pkgconfig
+"
+
+src_prepare() {
+       default
+
+       # Modify path to data
+       sed -i \
+               -e "s:arrfl:/usr/share/${PN}/arrfl:" \
+               -e 's:nm\[9:nm[35:' \
+               -e 's:nm\[6:nm[30:' \
+               -e 's:nm\[7:nm[31:' \
+               game.c \
+               || die 'sed failed'
+       sed -i \
+               -e '/^CC /d' \
+               -e '/CCLIBS/s:$: $(LDFLAGS):' \
+               Makefile \
+               || die 'sed failed'
+}
+
+src_compile() {
+       make clean || die "make clean failed"
+       emake CCOPTS="${CFLAGS}"
+}
+
+src_install() {
+       dobin arrows
+       insinto "/usr/share/${PN}"
+       doins arrfl*
+       einstalldocs
+}