media-plugins/gst-plugins-vaapi: Version bump

Package-Manager: portage-2.3.0

diff --git a/media-plugins/gst-plugins-vaapi/Manifest b/media-plugins/gst-plugins-vaapi/Manifest
index d1ea579da1498d3bbc716abd9c57df9e0609ca7c..49b7387924545b6e162af538f90fb61ccb39a4e3 100644 (file)
--- a/media-plugins/gst-plugins-vaapi/Manifest
+++ b/media-plugins/gst-plugins-vaapi/Manifest
@@ -1 +1,2 @@
 DIST gstreamer-vaapi-0.7.0.tar.bz2 2362818 SHA256 abe8ea4dfb3177d038b38610537c651b943707ed110882782a19b95a9ea04a92 SHA512 8594b97320b34c586fde0ab76f44cd6b8ee2404101259a65d2a457a89d75f158368c35471d85d82cd47beb5163fb075142fc2aeb0364566e1da7971a98a92357 WHIRLPOOL 4624d59a88482896da43da940c203181dcf66cd1ede82faa45efe200d30e1efda6872f08b758df2deadbce1fee476815ef0653f45234da81c1590c953ca613d5
+DIST gstreamer-vaapi-1.8.2.tar.xz 933152 SHA256 5479e86f593d80c00bbd4a43b16b2027cb935412a2bb22c9ba4ac085627a9229 SHA512 9ffd0fdba59c22f428c1c219d27ad83ebaa5c36c1a1fc875161b03438d69151f83218ce2766131daa71ba332b232c79e7723ad9fe2131b9baa8cf96b50dbf9bd WHIRLPOOL e89f0a7fa5c1084456c797f685cf273c144f25dc34e60b0a9519c662f9f9b9d8daf542abbd51bf79722294613bbe36fe9511b1d64d6022d0f90361cc73ca0480

diff --git a/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.8.2.ebuild b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.8.2.ebuild
new file mode 100644 (file)
index 0000000..c2c5860
--- /dev/null
+++ b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.8.2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils multilib-minimal
+
+MY_PN="gstreamer-vaapi"
+DESCRIPTION="Hardware accelerated video decoding through VA-API plugin"
+HOMEPAGE="https://cgit.freedesktop.org/gstreamer/gstreamer-vaapi"
+SRC_URI="https://gstreamer.freedesktop.org/src/${MY_PN}/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="1.0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="+drm opengl wayland +X"
+REQUIRED_USE="|| ( drm opengl wayland X )"
+
+RDEPEND="
+       >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
+       >=media-libs/gstreamer-${PV}:1.0[${MULTILIB_USEDEP}]
+       >=media-libs/gst-plugins-base-${PV}:1.0[${MULTILIB_USEDEP}]
+       >=media-libs/gst-plugins-bad-${PV}:1.0[opengl?,${MULTILIB_USEDEP}]
+       >=x11-libs/libva-1.4.0[drm?,X?,opengl?,wayland?,${MULTILIB_USEDEP}]
+       drm? (
+               >=virtual/libudev-208:=[${MULTILIB_USEDEP}]
+               >=x11-libs/libdrm-2.4.46[${MULTILIB_USEDEP}] )
+       X? (
+               >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+               >=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}] )
+       opengl? (
+               >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+               >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+               >=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}] )
+       wayland? ( >=dev-libs/wayland-1.0.6[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+       >=dev-util/gtk-doc-am-1.12
+       >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+multilib_src_configure() {
+       ECONF_SOURCE=${S} \
+       econf \
+               --disable-static \
+               --enable-egl \
+               $(use_enable drm) \
+               $(use_enable opengl glx) \
+               $(use_enable wayland) \
+               $(use_enable X x11)
+}
+
+multilib_src_install_all() {
+       einstalldocs
+       prune_libtool_files --modules
+}