dev-libs/squareball: first release. updated live ebuild

Package-Manager: portage-2.2.26

diff --git a/dev-libs/squareball/Manifest b/dev-libs/squareball/Manifest
new file mode 100644 (file)
index 0000000..f0b40e2
--- /dev/null
+++ b/dev-libs/squareball/Manifest
@@ -0,0 +1 @@
+DIST squareball-0.1.tar.xz 239784 SHA256 6af816486f9d6bc6ffe1375413b573047192cff935231269b1708c07356e0ecd SHA512 50e88af8ded3fdbf6d67de57931226740d1f66b370580ef3815443a0e95219a753f85bda111bb34874b32c267a5ce2ac5f7e4833d5c688b274e0459215c97a83 WHIRLPOOL 4202a381731df7313a1d57b0a67a8f7ef0a342fd54b32a6e6ae9f5d58bd3e36b2f87c847c1998a1823d8da0b615f6081be605b0d80a63e6e78bf9588ef471944

diff --git a/dev-libs/squareball/squareball-0.1.ebuild b/dev-libs/squareball/squareball-0.1.ebuild
new file mode 100644 (file)
index 0000000..2c9e5e3
--- /dev/null
+++ b/dev-libs/squareball/squareball-0.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+if [[ ${PV} = *9999* ]]; then
+       EGIT_REPO_URI="
+               git://github.com/rafaelmartins/squareball.git
+               https://github.com/rafaelmartins/squareball.git"
+       inherit git-r3 autotools
+fi
+
+inherit eutils
+
+DESCRIPTION="A general-purpose library for C99"
+HOMEPAGE="https://github.com/rafaelmartins/squareball"
+
+SRC_URI="https://github.com/rafaelmartins/${PN}/releases/download/v${PV}/${P}.tar.xz"
+KEYWORDS="~amd64 ~x86"
+if [[ ${PV} = *9999* ]]; then
+       SRC_URI=""
+       KEYWORDS=""
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test static-libs"
+
+RDEPEND=""
+
+DEPEND="
+       virtual/pkgconfig
+       test? (
+               dev-util/cmocka )
+       doc? (
+               app-doc/doxygen )"
+
+src_prepare() {
+       [[ ${PV} = *9999* ]] && eautoreconf
+       default
+}
+
+src_configure() {
+       econf \
+               $(use_enable doc) \
+               $(use_enable test tests) \
+               $(use_enable static-libs static) \
+               --disable-valgrind
+}
+
+src_compile() {
+       default
+       use doc && emake docs
+}
+
+src_install() {
+       use doc && HTML_DOCS=( doc/build/html/* )
+       default
+       prune_libtool_files --all
+}

diff --git a/dev-libs/squareball/squareball-9999.ebuild b/dev-libs/squareball/squareball-9999.ebuild
index e1e1c16524c36195bbfb41561dbaa685d4efa591..2c9e5e3ef293f3e41be81c071ce43d31f5314857 100644 (file)
--- a/dev-libs/squareball/squareball-9999.ebuild
+++ b/dev-libs/squareball/squareball-9999.ebuild
@@ -2,7 +2,7 @@
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
-EAPI=5
+EAPI=6
 
 if [[ ${PV} = *9999* ]]; then
        EGIT_REPO_URI="
@@ -29,10 +29,9 @@ IUSE="doc test static-libs"
 
 RDEPEND=""
 
-# pkg-config is used only to find cmocka libraries
-DEPEND="${DEPEND}
+DEPEND="
+       virtual/pkgconfig
        test? (
-               virtual/pkgconfig
                dev-util/cmocka )
        doc? (
                app-doc/doxygen )"
@@ -56,6 +55,7 @@ src_compile() {
 }
 
 src_install() {
+       use doc && HTML_DOCS=( doc/build/html/* )
        default
-       use doc && dohtml -r doc/build/html/*
+       prune_libtool_files --all
 }