app-arch/zstd: Fix ebuild

* Replace EROOT in src_* functions
* Call einstalldocs to install basic docs
* Use proper || die's for removing static libraries
* Pass CC and AR to make commands

Package-Manager: portage-2.3.2

diff --git a/app-arch/zstd/zstd-1.1.0.ebuild b/app-arch/zstd/zstd-1.1.0.ebuild
index bcfe360e065a47ac8b3b148e97cc0180ea77d77b..4e42b4fdc9d6afaacf0cfa53f32c0bb11ca49031 100644 (file)
--- a/app-arch/zstd/zstd-1.1.0.ebuild
+++ b/app-arch/zstd/zstd-1.1.0.ebuild
@@ -4,6 +4,8 @@
 
 EAPI=6
 
+inherit toolchain-funcs
+
 DESCRIPTION="zstd fast compression library"
 HOMEPAGE="http://facebook.github.io/zstd/"
 SRC_URI="https://github.com/facebook/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
@@ -16,15 +18,27 @@ IUSE="static-libs"
 PATCHES=( "${FILESDIR}/${P}-fix_build_system.patch" )
 
 src_compile() {
-       emake PREFIX="${EROOT}usr" LIBDIR="${EROOT}usr/$(get_libdir)" zstd
-       cd lib &&
-               emake PREFIX="${EROOT}usr" LIBDIR="${EROOT}usr/$(get_libdir)" libzstd
+       emake \
+               CC="$(tc-getCC)" \
+               AR="$(tc-getAR)" \
+               PREFIX="${EPREFIX}/usr" \
+               LIBDIR="${EPREFIX}/usr/$(get_libdir)" zstd
+
+       emake -C lib \
+               CC="$(tc-getCC)" \
+               AR="$(tc-getAR)" \
+               PREFIX="${EPREFIX}/usr" \
+               LIBDIR="${EPREFIX}/usr/$(get_libdir)" libzstd
 }
 
 src_install() {
-       emake DESTDIR="${D}" \
-               PREFIX="${EROOT}usr" LIBDIR="${EROOT}usr/$(get_libdir)" install
+       emake \
+               DESTDIR="${D}" \
+               PREFIX="${EPREFIX}/usr" \
+               LIBDIR="${EPREFIX}/usr/$(get_libdir)" install
+       einstalldocs
 
-       ! use static-libs &&
-               rm -f $ "${ED}usr/$(get_libdir)/libzstd.a"
+       if ! use static-libs; then
+               rm "${ED%/}"/usr/$(get_libdir)/libzstd.a || die
+       fi
 }