media-libs/libkate: Use the configure var to override PYTHON

Replace the 'sed' hack with a cleaner PYTHON=: configure override to
disable Python. This will make it possible to override it per-ABI.

diff --git a/media-libs/libkate/libkate-0.4.1-r3.ebuild b/media-libs/libkate/libkate-0.4.1-r3.ebuild
new file mode 100644 (file)
index 0000000..fe9f123
--- /dev/null
+++ b/media-libs/libkate/libkate-0.4.1-r3.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit ltprune python-single-r1
+
+DESCRIPTION="Codec for karaoke and text encapsulation for Ogg"
+HOMEPAGE="https://code.google.com/p/libkate/"
+SRC_URI="https://libkate.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+
+IUSE="debug doc wxwidgets"
+REQUIRED_USE="wxwidgets? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPEND="
+       media-libs/libogg:=
+       media-libs/libpng:0=
+"
+DEPEND="${COMMON_DEPEND}
+       virtual/pkgconfig
+       sys-devel/flex
+       sys-devel/bison
+       doc? ( app-doc/doxygen )
+"
+RDEPEND="${COMMON_DEPEND}
+       wxwidgets? (
+               ${PYTHON_DEPS}
+               dev-python/wxpython:3.0[${PYTHON_USEDEP}]
+               media-libs/liboggz )
+"
+
+pkg_setup() {
+       use wxwidgets && python-single-r1_pkg_setup
+}
+
+src_configure() {
+       econf \
+               --disable-static \
+               $(use_enable debug) \
+               $(use_enable doc) \
+               $(usex wxwidgets '' 'PYTHON=:')
+}
+
+src_install() {
+       default
+       prune_libtool_files
+       use wxwidgets && python_fix_shebang "${D}"
+}