dev-python/pyopenssl: Add python3.5 support

Package-Manager: portage-2.2.23
Signed-off-by: Justin Lecher <jlec@gentoo.org>

diff --git a/dev-python/pyopenssl/pyopenssl-0.15.1-r1.ebuild b/dev-python/pyopenssl/pyopenssl-0.15.1-r1.ebuild
new file mode 100644 (file)
index 0000000..6798618
--- /dev/null
+++ b/dev-python/pyopenssl/pyopenssl-0.15.1-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} pypy )
+
+inherit distutils-r1 flag-o-matic
+
+MY_PN=pyOpenSSL
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python interface to the OpenSSL library"
+HOMEPAGE="
+       http://pyopenssl.sourceforge.net/
+       https://launchpad.net/pyopenssl
+       https://pypi.python.org/pypi/pyOpenSSL
+"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris"
+IUSE="doc examples"
+
+RDEPEND="
+       >=dev-python/six-1.5.2[${PYTHON_USEDEP}]
+       >=dev-python/cryptography-0.7[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+       doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+S=${WORKDIR}/${MY_P}
+
+python_prepare_all() {
+       # https://github.com/pyca/pyopenssl/issues/41
+       sed -e "s/test_digest/_&/" -i OpenSSL/test/test_crypto.py
+
+       distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+       use doc && emake -C doc html
+}
+
+python_test() {
+       esetup.py test
+
+       # https://bugs.launchpad.net/pyopenssl/+bug/1237953
+       rm -rf tmp* *.key *.pem || die
+}
+
+python_install_all() {
+       use doc && local HTML_DOCS=( doc/_build/html/. )
+       use examples && local EXAMPLES=( examples/. )
+       distutils-r1_python_install_all
+}

diff --git a/dev-python/pyopenssl/pyopenssl-0.15.1.ebuild b/dev-python/pyopenssl/pyopenssl-0.15.1.ebuild
index e42ac7de7044dee14b9758f781f70c9dffef177f..51f0a602c591afc9002b9866f1224e68519fd038 100644 (file)
--- a/dev-python/pyopenssl/pyopenssl-0.15.1.ebuild
+++ b/dev-python/pyopenssl/pyopenssl-0.15.1.ebuild
@@ -4,7 +4,7 @@
 
 EAPI=5
 
-PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy pypy3 )
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
 
 inherit distutils-r1 flag-o-matic